[arch-commits] Commit in openimagedenoise/trunk (PKGBUILD)

[Filipe Laíns]

    Date: Tuesday, November 26, 2019 @ 11:38:01
  Author: ffy00
Revision: 533459

upgpkg: openimagedenoise 1.1.0-1

Added:
  openimagedenoise/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-11-26 11:38:01 UTC (rev 533459)
@@ -0,0 +1,45 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+pkgname=openimagedenoise
+_pkgname=oidn
+pkgver=1.1.0
+pkgrel=1
+pkgdesc='Intel(R) Open Image Denoise library'
+arch=('x86_64')
+url='https://openimagedenoise.github.io'
+license=('Apache')
+depends=('intel-tbb' 'python')
+makedepends=('git' 'cmake')
+source=("git+https://github.com/OpenImageDenoise/oidn#tag=v$pkgver"
+        'git+https://github.com/OpenImageDenoise/oidn-weights'
+        "oidn-mkl-dnn::git+https://github.com/OpenImageDenoise/mkl-dnn")
+sha512sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+prepare() {
+    cd $_pkgname
+
+    git submodule init
+    git config submodule.weights.url "$srcdir"/oidn-weights
+    git config submodule.mkl-dnn.url "$srcdir"/oidn-mkl-dnn
+    git submodule update
+}
+
+build() {
+    mkdir $_pkgname/build
+    cd $_pkgname/build
+
+    cmake .. \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=Release
+
+    make
+}
+
+package() {
+    cd $_pkgname/build
+
+    make DESTDIR="$pkgdir" install
+}
+