[arch-commits] Commit in qgis/repos (2 files)

[Antonio Rojas]

    Date: Friday, November 29, 2019 @ 19:59:36
  Author: arojas
Revision: 534531

archrelease: copy trunk to community-staging-x86_64

Added:
  qgis/repos/community-staging-x86_64/
  qgis/repos/community-staging-x86_64/PKGBUILD
    (from rev 534530, qgis/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: qgis/repos/community-staging-x86_64/PKGBUILD (from rev 534530, qgis/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-29 19:59:36 UTC (rev 534531)
@@ -0,0 +1,60 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Doug Newgard <scimmia at archlinux dot org>
+# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
+# Contributor: SaultDon <sault.don gmail>
+# Contributor: Lantald < lantald at gmx.com >
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at yahoo.com.ar>
+# Contributor: Eric Forgeot < http://esclinux.tk >
+
+pkgname=qgis
+pkgver=3.10.0
+pkgrel=1
+pkgdesc='Geographic Information System (GIS) that supports vector, raster & database formats'
+url='https://qgis.org/'
+license=(GPL)
+arch=(x86_64)
+depends=(desktop-file-utils exiv2 gdal hicolor-icon-theme libzip python-qscintilla-qt5 qca qt5-3d
+         qt5-serialport qt5-webkit qtkeychain qwtpolar spatialindex python-sip)
+makedepends=(cmake fcgi gsl python-six qt5-tools txt2tags sip)
+optdepends=('fcgi: Map server'
+            'gpsbabel: GPS Tools plugin'
+            'gsl: Georeferencer plugin'
+            'python-gdal: DB Manager plugin; Processing plugin'
+            'python-jinja: MetaSearch plugin'
+            'python-owslib: MetaSearch plugin'
+            'python-psycopg2: DB Manager plugin; Processing plugin'
+            'python-pygments: MetaSearch plugin'
+            'python-numpy: Processing plugin'
+            'python-yaml: Processing plugin')
+source=("https://qgis.org/downloads/$pkgname-$pkgver.tar.bz2"
+         qgis-fix-dependency.patch::"https://github.com/qgis/QGIS/commit/319ee306.patch")
+sha256sums=('25eb1c41d9fb922ffa337a720dfdceee43cf2d38409923f087c2010c9742f012'
+            '92f255dfa0eba785dbf278fe87c08468b0546b4fe330a720596b883f0bb82b3f')
+
+prepare() {
+  [[ -d build ]] || mkdir build
+
+  cd $pkgname-$pkgver
+  patch -p1 -i ../qgis-fix-dependency.patch # Fix race
+}
+
+build() {
+  cd build
+  cmake -G "Unix Makefiles" ../$pkgname-$pkgver/ \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DWITH_3D=TRUE \
+    -DWITH_SERVER=TRUE \
+    -DWITH_CUSTOM_WIDGETS=TRUE \
+    -DBINDINGS_GLOBAL_INSTALL=TRUE \
+    -DQGIS_MANUAL_SUBDIR=share/man \
+    -DWITH_QWTPOLAR=TRUE \
+    -DWITH_INTERNAL_QWTPOLAR=FALSE
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}