[arch-commits] Commit in (kvazaar kvazaar/repos kvazaar/trunk kvazaar/trunk/PKGBUILD)

Daniel Bermond dbermond at archlinux.org
Tue Oct 1 18:23:23 UTC 2019


    Date: Tuesday, October 1, 2019 @ 18:23:23
  Author: dbermond
Revision: 512376

Initial commit of kvazaar

Added:
  kvazaar/
  kvazaar/repos/
  kvazaar/trunk/
  kvazaar/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: kvazaar/trunk/PKGBUILD
===================================================================
--- kvazaar/trunk/PKGBUILD	                        (rev 0)
+++ kvazaar/trunk/PKGBUILD	2019-10-01 18:23:23 UTC (rev 512376)
@@ -0,0 +1,44 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+
+pkgname=kvazaar
+pkgver=1.3.0
+pkgrel=1
+pkgdesc='An open-source HEVC encoder'
+arch=('x86_64')
+url='http://ultravideo.cs.tut.fi/#encoder'
+license=('LGPL')
+depends=('glibc' 'gcc-libs' 'crypto++')
+makedepends=('git' 'yasm')
+checkdepends=('ffmpeg' 'hm')
+source=("git+https://github.com/ultravideo/kvazaar.git#tag=v${pkgver}"
+        'git+https://github.com/ultravideo/greatest.git')
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+    cd kvazaar
+    
+    git submodule init
+    git config --local submodule.greatest.url "${srcdir}/greatest"
+    git submodule update
+    
+    ./autogen.sh
+}
+
+build() {
+    cd kvazaar
+    
+    ./configure \
+        --prefix='/usr' \
+        --with-cryptopp
+        
+    make
+}
+
+check() {
+    make -C kvazaar check
+}
+
+package() {
+    make -C kvazaar DESTDIR="$pkgdir" install
+}



More information about the arch-commits mailing list