[arch-commits] Commit in (5 files)

[Daniel Bermond]

    Date: Thursday, October 3, 2019 @ 11:59:03
  Author: dbermond
Revision: 512491

Initial commit os mujs

Added:
  mujs/
  mujs/repos/
  mujs/trunk/
  mujs/trunk/010-mujs-use-arch-flags.patch
  mujs/trunk/PKGBUILD

-------------------------------+
 010-mujs-use-arch-flags.patch |   21 +++++++++++++++++++++
 PKGBUILD                      |   31 +++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

Added: mujs/trunk/010-mujs-use-arch-flags.patch
===================================================================
--- mujs/trunk/010-mujs-use-arch-flags.patch	                        (rev 0)
+++ mujs/trunk/010-mujs-use-arch-flags.patch	2019-10-03 11:59:03 UTC (rev 512491)
@@ -0,0 +1,21 @@
+diff -Naurp a/Makefile b/Makefile
+--- a/Makefile	2018-09-11 10:47:31.000000000 +0000
++++ b/Makefile	2018-12-16 20:19:17.793566976 +0000
+@@ -15,7 +15,7 @@ endif
+ 
+ # Compiler flags for various configurations:
+ 
+-CFLAGS := -std=c99 -pedantic -Wall -Wextra -Wno-unused-parameter
++CFLAGS += -std=c99 -pedantic -Wall -Wextra -Wno-unused-parameter
+ 
+ ifeq "$(CC)" "clang"
+   CFLAGS += -Wunreachable-code
+@@ -78,7 +78,7 @@ $(OUT)/libmujs.a: $(OUT)/libmujs.o
+ 
+ $(OUT)/libmujs.so: one.c $(HDRS)
+ 	@ mkdir -p $(dir $@)
+-	$(CC) $(CFLAGS) -fPIC -shared -o $@ $< -lm
++	$(CC) $(CFLAGS) -fPIC -shared $(LDFLAGS) -o $@ $< -lm
+ 
+ $(OUT)/mujs: $(OUT)/libmujs.o $(OUT)/main.o
+ 	@ mkdir -p $(dir $@)

Added: mujs/trunk/PKGBUILD
===================================================================
--- mujs/trunk/PKGBUILD	                        (rev 0)
+++ mujs/trunk/PKGBUILD	2019-10-03 11:59:03 UTC (rev 512491)
@@ -0,0 +1,31 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+
+pkgname=mujs
+pkgver=1.0.6
+pkgrel=1
+pkgdesc='An embeddable Javascript interpreter in C'
+arch=('x86_64')
+url='https://mujs.com/'
+license=('ISC')
+depends=('readline')
+source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/ccxvii/mujs/archive/${pkgver}.tar.gz"
+        '010-mujs-use-arch-flags.patch')
+sha256sums=('a444d8ea22b18eff89acbc7f9e45cc95e5b63b30ae8f4b8000b858cd17006f2d'
+            '051c8a8727f4ff2816e9c060fbe969b7d1e8b9e2c07d704e809c24ff4394f0f4')
+
+prepare() {
+    patch -d "${pkgname}-${pkgver}" -Np1 -i "${srcdir}/010-mujs-use-arch-flags.patch"
+}
+
+build() {
+    make -C "${pkgname}-${pkgver}" release
+}
+
+package() {
+    mkdir -p "${pkgdir}/usr/share/doc/${pkgname}"
+    
+    make -C "${pkgname}-${pkgver}" DESTDIR="$pkgdir" prefix='/usr' install-shared
+    
+    install -D -m644 "${pkgname}-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/mujs/LICENSE"
+    install    -m644 "${pkgname}-${pkgver}/docs/"*  "${pkgdir}/usr/share/doc/${pkgname}"
+}