[arch-commits] Commit in libmicrohttpd/repos (2 files)

[Christian Hesse]

    Date: Thursday, October 17, 2019 @ 18:49:28
  Author: eworm
Revision: 516548

archrelease: copy trunk to community-testing-x86_64

Added:
  libmicrohttpd/repos/community-testing-x86_64/
  libmicrohttpd/repos/community-testing-x86_64/PKGBUILD
    (from rev 516547, libmicrohttpd/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: libmicrohttpd/repos/community-testing-x86_64/PKGBUILD (from rev 516547, libmicrohttpd/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-10-17 18:49:28 UTC (rev 516548)
@@ -0,0 +1,44 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Norberto Lopes <shelika at mail.telepac.pt>
+# Contributor: Kao Dome <kaodome at gmail.com>
+# Contributor: Dmitrij D. Czarkoff <czarkoff at gmail.com>
+# Contributor: Mathias Rohnstock <linksoft at gmx.de>
+
+pkgname=libmicrohttpd
+pkgver=0.9.67
+pkgrel=1
+pkgdesc="a small C library that is supposed to make it easy to run an HTTP server as part of another application."
+arch=('x86_64')
+url="https://www.gnu.org/software/libmicrohttpd/"
+license=('LGPL')
+depends=('gnutls')
+checkdepends=('curl')
+validpgpkeys=('EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'  # Evgeny Grin (Karlson2k) <k2k at yandex.ru>
+              'D8423BCB326C7907033929C7939E6BE1E29FC3CC') # Christian Grothoff <christian.grothoff at bfh.ch>
+source=("https://ftp.gnu.org/gnu/libmicrohttpd/$pkgname-$pkgver.tar.gz"{,.sig})
+sha256sums=('7e1f852723d099d4827d7ebde4d02dd00fd8da62149526fdb9fae058c5a60495'
+            'SKIP')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --disable-dependency-tracking \
+    --disable-examples \
+    --enable-curl \
+    --enable-https \
+    --enable-largefile \
+    --enable-messages \
+    --with-pic
+  make
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  make check
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="$pkgdir" install
+}