[arch-commits] Commit in nvidia-lts/repos (3 files)

[Andreas Radke]

    Date: Friday, October 18, 2019 @ 09:01:20
  Author: andyrtr
Revision: 365133

archrelease: copy trunk to testing-x86_64

Added:
  nvidia-lts/repos/testing-x86_64/
  nvidia-lts/repos/testing-x86_64/PKGBUILD
    (from rev 365132, nvidia-lts/trunk/PKGBUILD)
  nvidia-lts/repos/testing-x86_64/fs62142.patch
    (from rev 365132, nvidia-lts/trunk/fs62142.patch)

---------------+
 PKGBUILD      |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 fs62142.patch |   13 +++++++++++++
 2 files changed, 59 insertions(+)

Copied: nvidia-lts/repos/testing-x86_64/PKGBUILD (from rev 365132, nvidia-lts/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-10-18 09:01:20 UTC (rev 365133)
@@ -0,0 +1,46 @@
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgname=nvidia-lts
+pkgver=435.21
+pkgrel=6
+epoch=1
+pkgdesc="NVIDIA drivers for linux-lts"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=("nvidia-utils=${pkgver}" 'libglvnd' 'linux-lts' 'linux-lts-headers>=4.19.80')
+provides=('nvidia')
+license=('custom')
+options=('!strip')
+_pkg="NVIDIA-Linux-x86_64-${pkgver}"
+source=("https://us.download.nvidia.com/XFree86/Linux-x86_64/${pkgver}/${_pkg}.run"
+        fs62142.patch)
+sha512sums=('e83b6dff80434971c0b254815945d485a45c978b8a19994244f50a463658863948b2eac8bc62d667bb10c23f41cf1c3521c409d23ac2ab6a0c0cd094a6e20270'
+            'df949debf9fed92b3c58322c02685fb344bbfff2920557e7d55ed3f70559f48cd6199bc85e2af170b7e56797f3e9881a53eab8c411f21e75f5abec26eaa47752')
+
+prepare() {
+    sh "${_pkg}.run" --extract-only
+    cd "${_pkg}"
+
+    # Fix https://bugs.archlinux.org/task/62142
+    patch -Np1 -i ../fs62142.patch
+}
+
+build() {
+    cd "${_pkg}"/kernel
+    make SYSSRC=/usr/src/linux-lts module
+}
+
+package() {
+    depends=('linux-lts>=4.19.80' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _extradir="/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules"
+    install -Dt "${pkgdir}${_extradir}" -m644 \
+      "${srcdir}/${_pkg}/kernel"/nvidia{,-modeset,-drm,-uvm}.ko
+
+    find "${pkgdir}" -name '*.ko' -exec gzip -n {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 "${srcdir}/${_pkg}/LICENSE"
+}

Copied: nvidia-lts/repos/testing-x86_64/fs62142.patch (from rev 365132, nvidia-lts/trunk/fs62142.patch)
===================================================================
--- testing-x86_64/fs62142.patch	                        (rev 0)
+++ testing-x86_64/fs62142.patch	2019-10-18 09:01:20 UTC (rev 365133)
@@ -0,0 +1,13 @@
+diff --git a/kernel/nvidia/nv-dma.c b/kernel/nvidia/nv-dma.c
+index 73cdeed..e691014 100644
+--- a/kernel/nvidia/nv-dma.c
++++ b/kernel/nvidia/nv-dma.c
+@@ -606,7 +606,7 @@ static NvBool nv_dma_is_map_resource_implemented
+ #if defined(NV_DMA_MAP_RESOURCE_PRESENT)
+     const struct dma_map_ops *ops = get_dma_ops(&nvl->dev->dev);
+ 
+-    return (ops->map_resource != NULL);
++    return (ops && ops->map_resource);
+ #else
+     return NV_FALSE;
+ #endif