[arch-commits] Commit in ogre/repos (3 files)

[Antonio Rojas]

    Date: Saturday, October 19, 2019 @ 08:02:12
  Author: arojas
Revision: 517414

archrelease: copy trunk to community-staging-x86_64

Added:
  ogre/repos/community-staging-x86_64/
  ogre/repos/community-staging-x86_64/PKGBUILD
    (from rev 517413, ogre/trunk/PKGBUILD)
  ogre/repos/community-staging-x86_64/ogre.install
    (from rev 517413, ogre/trunk/ogre.install)

--------------+
 PKGBUILD     |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 ogre.install |    3 ++
 2 files changed, 70 insertions(+)

Copied: ogre/repos/community-staging-x86_64/PKGBUILD (from rev 517413, ogre/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-19 08:02:12 UTC (rev 517414)
@@ -0,0 +1,67 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+pkgbase=ogre
+pkgname=('ogre' 'ogre-docs')
+pkgver=1.12.2
+pkgrel=2
+pkgdesc='Scene-oriented, flexible 3D engine written in C++'
+arch=('x86_64')
+url='http://www.ogre3d.org'
+license=('custom:MIT')
+depends=('freeimage' 'freetype2' 'libxaw' 'libxrandr' 'openexr' 'pugixml'
+         'nvidia-cg-toolkit' 'zziplib' 'sdl2' 'glu' 'tinyxml')
+makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'python' 'swig' 'systemd')
+install=ogre.install
+source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz")
+sha512sums=('557a9ca85f5ac5a41ff7ef06622723e04b008f3e9dc90d44b13ed05f34b5bf23cf9a1959d94d34a12dc0750eeb3b4550d62ba5102379d1b2825753b2b0a836d7')
+
+prepare() {
+  mkdir ogre-${pkgver}/build
+}
+
+build() {
+  cd ogre-${pkgver}/build
+
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DOGRE_BUILD_DEPENDENCIES=FALSE \
+    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
+    -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
+    -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE
+
+  make
+  make OgreDoc
+}
+
+package_ogre() {
+  optdepends=('cppunit: unit testing'
+              'python: python bindings'
+              'ogre-docs: documentation')
+
+  cd ogre-${pkgver}/build
+
+  make DESTDIR=${pkgdir} install
+
+  mv ${pkgdir}/usr/bin/SampleBrowser ${pkgdir}/usr/bin/OgreSampleBrowser
+  install -Dm644 ../LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+
+  # move docs out of this package
+  mv ${pkgdir}/usr/share/OGRE/docs ${srcdir}/docs
+}
+
+package_ogre-docs() {
+  pkgdesc="Documentation for ogre"
+  depends=()
+
+  cd ogre-${pkgver}/build
+
+  # move docs into this package
+  install -dm755 ${pkgdir}/usr/share/doc
+  mv ${srcdir}/docs ${pkgdir}/usr/share/doc/OGRE/
+
+  # symlink for docs
+  install -dm755 ${pkgdir}/usr/share/OGRE/
+  cd ${pkgdir}/usr/share
+  ln -s /usr/share/doc/OGRE/ OGRE/docs
+}
+
+# vim:set ts=2 sw=2 et:

Copied: ogre/repos/community-staging-x86_64/ogre.install (from rev 517413, ogre/trunk/ogre.install)
===================================================================
--- community-staging-x86_64/ogre.install	                        (rev 0)
+++ community-staging-x86_64/ogre.install	2019-10-19 08:02:12 UTC (rev 517414)
@@ -0,0 +1,3 @@
+post_install() {
+    echo "To view the OGRE samples just run OgreSampleBrowser"
+}