[arch-commits] Commit in pax/repos (community-x86_64 community-x86_64/PKGBUILD)

[Daniel Bermond]

    Date: Tuesday, October 22, 2019 @ 14:00:25
  Author: dbermond
Revision: 518344

archrelease: copy trunk to community-x86_64

Added:
  pax/repos/community-x86_64/
  pax/repos/community-x86_64/PKGBUILD
    (from rev 518343, pax/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: pax/repos/community-x86_64/PKGBUILD (from rev 518343, pax/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2019-10-22 14:00:25 UTC (rev 518344)
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+pkgname=pax
+pkgver=20190825
+pkgrel=1
+pkgdesc='Portable Archive Interchange - the POSIX standard archive tool for cpio and tar formats'
+arch=('x86_64')
+url='https://www.mirbsd.org/pax.htm'
+license=('BSD')
+depends=('glibc')
+source=("https://www.mirbsd.org/MirOS/dist/mir/cpio/paxmirabilis-${pkgver}.cpio.gz")
+noextract=("paxmirabilis-${pkgver}.cpio.gz")
+sha256sums=('94c9110e4778d762523c3915b97587b92ae4547129424e34ad4512da4eb09b81')
+
+prepare() {
+    mkdir -p "${pkgname}-${pkgver}/build"
+    bsdtar -x -f "paxmirabilis-${pkgver}.cpio.gz" -C "$pkgname-${pkgver}" --strip-components='1'
+}
+
+build() {
+    cd "${pkgname}-${pkgver}/build"
+    sh ../Build.sh -r -tpax
+    
+    # license
+    sed -n '5,36p' ../pax.h > LICENSE # create file
+    sed -i '1,32s/^.\{,3\}//' LICENSE # erase C comments
+}
+
+package(){
+    # executables
+    install -D -m755 "${pkgname}-${pkgver}/build/pax" -t "${pkgdir}/usr/bin"
+    ln -s pax "${pkgdir}/usr/bin/paxcpio"
+    ln -s pax "${pkgdir}/usr/bin/paxtar"
+    
+    # man pages
+    install -D -m644 "${pkgname}-${pkgver}/build/mans/"*.1 -t "${pkgdir}/usr/share/man/man1"
+    
+    # license
+    install -D -m644 "${pkgname}-${pkgver}/build/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}