[arch-commits] Commit in knot/repos (3 files)

[Jelle van der Waa]

    Date: Wednesday, October 23, 2019 @ 18:32:05
  Author: jelle
Revision: 518753

db-move: moved knot from [community-staging] to [community-testing] (x86_64)

Added:
  knot/repos/community-testing-x86_64/
  knot/repos/community-testing-x86_64/PKGBUILD
    (from rev 518752, knot/repos/community-staging-x86_64/PKGBUILD)
Deleted:
  knot/repos/community-staging-x86_64/

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: knot/repos/community-testing-x86_64/PKGBUILD (from rev 518752, knot/repos/community-staging-x86_64/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-10-23 18:32:05 UTC (rev 518753)
@@ -0,0 +1,61 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Ondřej Surý <ondrej at sury.org>
+# Contributor: Julian Brost <julian at 0x4a42.net>
+# Contributor: Oleander Reis <oleander at oleander.cc>
+# Contributor: Otto Sabart <seberm[at]gmail[dot]com>
+
+pkgname=knot
+pkgver=2.9.0
+pkgrel=1
+pkgdesc="High-performance authoritative-only DNS server"
+arch=(x86_64)
+url="https://www.knot-dns.cz/"
+license=(GPL3)
+depends=(libedit gnutls liburcu lmdb
+         libidn2 systemd libcap-ng
+         fstrm protobuf-c libmaxminddb)
+backup=('etc/knot/knot.conf')
+source=("https://secure.nic.cz/files/knot-dns/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha256sums=(df7434eaefbabbf7cca2d6cba5038be48a4668e508215ca197532bac7c9b21a2 SKIP)
+validpgpkeys=(742FA4E95829B6C5EAC6B85710BB7AF6FEBBD6AB) # Daniel Salzman <daniel.salzman at nic.cz>
+
+build() {
+    cd ${pkgname}-${pkgver}
+
+    ./configure \
+        --prefix=/usr \
+        --sbindir=/usr/bin \
+        --sysconfdir=/etc \
+        --localstatedir=/var/lib \
+        --libexecdir=/usr/lib/knot \
+        --with-rundir=/run/knot \
+        --with-storage=/var/lib/knot \
+        --enable-recvmmsg \
+        --enable-dnstap \
+        --enable-systemd \
+        --enable-reuseport \
+        --disable-silent-rules
+
+    make
+}
+
+check() {
+    cd ${pkgname}-${pkgver}
+    make check
+}
+
+package() {
+    cd ${pkgname}-${pkgver}
+
+    make DESTDIR="${pkgdir}" install
+
+    # Don’t keep those empty dir, manage them with systemd-tmpfiles instead
+    rmdir "${pkgdir}"/{var/{lib/{knot/,},},run/{knot/,}}
+
+    rm "${pkgdir}"/etc/knot/example.com.zone
+    mv "${pkgdir}"/etc/knot/{knot.sample.conf,knot.conf}
+
+    install -Dm644 distro/common/knot.service -t "${pkgdir}"/usr/lib/systemd/system/
+    install -Dm644 distro/arch/knot.tmpfiles.arch "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname}.conf
+    install -Dm644 distro/arch/knot.sysusers "${pkgdir}"/usr/lib/sysusers.d/${pkgname}.conf
+}