[arch-commits] Commit in python-whoosh/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:15:31
  Author: felixonmars
Revision: 518946

archrelease: copy trunk to community-staging-any

Added:
  python-whoosh/repos/community-staging-any/
  python-whoosh/repos/community-staging-any/PKGBUILD
    (from rev 518943, python-whoosh/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-whoosh/repos/community-staging-any/PKGBUILD (from rev 518943, python-whoosh/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 15:15:31 UTC (rev 518946)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Samuel Littley <aur at toastwaffle.com>
+# Contributor: rnons <remotenonsense at gmail dot com>
+
+pkgbase=python-whoosh
+pkgname=(python-whoosh python2-whoosh)
+pkgver=2.7.4
+pkgrel=4
+pkgdesc="Fast, pure-Python full text indexing, search, and spell checking library"
+arch=('any')
+url="https://bitbucket.org/mchaput/whoosh/wiki/Home"
+license=("BSD")
+makedepends=('python-setuptools' 'python2-setuptools' 'mercurial')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("hg+https://bitbucket.org/mchaput/whoosh#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a whoosh{,-py2}
+}
+
+build() {
+  cd "$srcdir"/whoosh
+  python setup.py build
+
+  cd "$srcdir"/whoosh-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/whoosh
+  python setup.py ptr || warning "Tests failed"
+
+  cd "$srcdir"/whoosh-py2
+  python2 setup.py ptr || warning "Tests failed"
+}
+
+package_python-whoosh() {
+  depends=('python')
+
+  cd whoosh
+  python setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python2-whoosh() {
+  depends=('python2')
+
+  cd whoosh-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}