[arch-commits] Commit in python-asn1crypto/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:18:51
  Author: felixonmars
Revision: 365610

archrelease: copy trunk to staging-any

Added:
  python-asn1crypto/repos/staging-any/
  python-asn1crypto/repos/staging-any/PKGBUILD
    (from rev 365609, python-asn1crypto/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-asn1crypto/repos/staging-any/PKGBUILD (from rev 365609, python-asn1crypto/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-10-25 15:18:51 UTC (rev 365610)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Massimiliano Torromeo < massimiliano DOT torromeo AT gmail DOT com >
+
+pkgbase=python-asn1crypto
+pkgname=('python-asn1crypto' 'python2-asn1crypto')
+pkgver=1.2.0
+pkgrel=2
+arch=('any')
+license=('MIT')
+pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
+url="https://github.com/wbond/asn1crypto"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
+sha512sums=('00d7d67e717fde9651aacc35141b872e4fcb6c46457af5e971aceae7f9acf1d018dfef94eddfa05eac7c7f3a4c768edc8a1ca0474101c1e77ee377aa4771274b')
+
+prepare() {
+  cp -a asn1crypto-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/asn1crypto-$pkgver
+  python run.py tests
+
+  cd "$srcdir"/asn1crypto-$pkgver-py2
+  python2 run.py tests
+}
+
+package_python-asn1crypto() {
+  depends=('python')
+
+  cd asn1crypto-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
+}
+
+package_python2-asn1crypto() {
+  depends=('python2')
+
+  cd asn1crypto-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python2-asn1crypto/LICENSE
+}