[arch-commits] Commit in python-wheel/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:21:20
  Author: felixonmars
Revision: 518994

archrelease: copy trunk to community-staging-any

Added:
  python-wheel/repos/community-staging-any/
  python-wheel/repos/community-staging-any/PKGBUILD
    (from rev 518992, python-wheel/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: python-wheel/repos/community-staging-any/PKGBUILD (from rev 518992, python-wheel/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 15:21:20 UTC (rev 518994)
@@ -0,0 +1,67 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: Lance Chen <cyen0312 at gmail.com>
+
+_pypiname=wheel
+pkgbase=python-wheel
+pkgname=('python-wheel' 'python2-wheel')
+pkgver=0.33.6
+pkgrel=2
+pkgdesc="A built-package format for Python"
+arch=(any)
+url="https://pypi.python.org/pypi/wheel"
+license=('MIT')
+makedepends=('python' 'python-setuptools'
+             'python2' 'python2-setuptools')
+checkdepends=('python-jsonschema' 'python2-jsonschema' 'python-pytest-cov' 'python2-pytest-cov'
+              'python-keyring' 'python-keyrings-alt' 'python-xdg' 'python2-xdg')
+source=("https://pypi.io/packages/source/w/wheel/$_pypiname-$pkgver.tar.gz")
+source=("$pkgname-$pkgver.tar.gz::https://github.com/pypa/wheel/archive/$pkgver.tar.gz")
+sha512sums=('04edf619ee6fd06f1e4c8bc513c6e21ba91615eba42bca5473e60573e274133b1019774b8e3a960e05f5a69bb256508d0a8a31fd9ab91a28f1b87d1095b17b5e')
+
+prepare() {
+  cp -a wheel-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/wheel-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/wheel-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir/wheel-$pkgver"
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.8/site-packages:$PYTHONPATH" py.test
+
+  cd "$srcdir/wheel-$pkgver-py2"
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH" py.test2 -k 'not test_keygen'
+}
+
+package_python-wheel() {
+  depends=('python')
+  optdepends=('python-keyring: for wheel.signatures')
+  optdepends=('python-xdg: for wheel.signatures')
+
+  cd "$srcdir/$_pypiname-$pkgver"
+  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-wheel() {
+  depends=('python2')
+  optdepends=('python2-keyring: for wheel.signatures')
+  optdepends=('python2-xdg: for wheel.signatures')
+
+  cd "$srcdir/$_pypiname-$pkgver"
+  python2 setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+  install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+  mv "$pkgdir/usr/bin/wheel" "$pkgdir/usr/bin/wheel2"
+}
+
+# vim:set ts=2 sw=2 et: