[arch-commits] Commit in python-billiard/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:23:23
  Author: felixonmars
Revision: 519008

archrelease: copy trunk to community-staging-x86_64

Added:
  python-billiard/repos/community-staging-x86_64/
  python-billiard/repos/community-staging-x86_64/PKGBUILD
    (from rev 519006, python-billiard/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-billiard/repos/community-staging-x86_64/PKGBUILD (from rev 519006, python-billiard/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-25 15:23:23 UTC (rev 519008)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Benjamin A. Shelton <zancarius at gmail.com>
+# Source: https://github.com/zancarius/archlinux-pkgbuilds
+
+pkgbase=python-billiard
+pkgname=('python-billiard' 'python2-billiard')
+pkgver=3.6.1.0
+pkgrel=2
+pkgdesc="Python multiprocessing fork with improvements and bugfixes."
+arch=('x86_64')
+url="https://pypi.org/project/billiard/"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-case' 'python2-case'
+              'python-psutil' 'python2-psutil')
+source=("https://pypi.io/packages/source/b/billiard/billiard-$pkgver.tar.gz")
+sha512sums=('d0250d30bc22340ef0931df6c909c6353fcda486d0a9100c3ec922ce8284bb0b359faba2d696ddc3ddb8eb4dc7d8e07fe7e2f2cf3244b67a5ed90ebad8c5f68b')
+
+prepare() {
+  sed -i 's/< *5/<6/' billiard-$pkgver/requirements/test.txt
+  cp -a billiard-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-billiard() {
+  depends=('python')
+
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm0664 "$srcdir"/billiard-$pkgver/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-billiard() {
+  depends=('python2')
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm0664 "$srcdir"/billiard-$pkgver/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}