[arch-commits] Commit in python-jsonpickle/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:36:47
  Author: felixonmars
Revision: 519114

archrelease: copy trunk to community-staging-any

Added:
  python-jsonpickle/repos/community-staging-any/
  python-jsonpickle/repos/community-staging-any/PKGBUILD
    (from rev 519111, python-jsonpickle/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-jsonpickle/repos/community-staging-any/PKGBUILD (from rev 519111, python-jsonpickle/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 15:36:47 UTC (rev 519114)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-jsonpickle
+pkgname=(python-jsonpickle python2-jsonpickle)
+pkgver=1.2
+pkgrel=2
+arch=('any')
+pkgdesc="Python library for serializing any arbitrary object graph into JSON"
+url="https://jsonpickle.github.io/"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-nose-show-skipped' 'python2-nose-show-skipped' 'python-numpy' 'python2-numpy'
+              'python-feedparser' 'python2-feedparser' 'python-coverage' 'python2-coverage' 'python2-enum34'
+              'python-simplejson' 'python2-simplejson' 'python-pymongo' 'python2-pymongo' 'python-ujson'
+              'python2-ujson')
+license=('BSD')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/jsonpickle/jsonpickle/archive/v$pkgver.tar.gz")
+sha512sums=('32bcb3df5d2833a52e52d27f6594124119c33f2ad7c111074da4670711f8651c208f4bb1ec826752044b3b2d19053860679d124d9a81f9e303d1377f1e3900c0')
+
+prepare() {
+  cp -a jsonpickle-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/jsonpickle-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/jsonpickle-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/jsonpickle-$pkgver
+  nosetests3 --show-skipped
+
+  cd "$srcdir"/jsonpickle-$pkgver-py2
+  nosetests2 --show-skipped
+}
+
+package_python-jsonpickle() {
+  depends=('python')
+
+  cd jsonpickle-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}
+
+package_python2-jsonpickle() {
+  depends=('python2')
+
+  cd jsonpickle-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
+}