[arch-commits] Commit in python-simplejson/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 15:44:25
  Author: felixonmars
Revision: 519179

archrelease: copy trunk to community-staging-x86_64

Added:
  python-simplejson/repos/community-staging-x86_64/
  python-simplejson/repos/community-staging-x86_64/PKGBUILD
    (from rev 519178, python-simplejson/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-simplejson/repos/community-staging-x86_64/PKGBUILD (from rev 519178, python-simplejson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-25 15:44:25 UTC (rev 519179)
@@ -0,0 +1,58 @@
+# Maintainer: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jaroslav Lichtblau <dragonlord at aur.archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: David Moore <davidm at sjsoft.com>
+
+pkgbase=python-simplejson
+pkgname=('python-simplejson' 'python2-simplejson')
+pkgver=3.16.1
+pkgrel=2
+pkgdesc='Simple, fast, extensible JSON encoder/decoder for Python'
+license=('MIT')
+arch=('x86_64')
+url='https://github.com/simplejson/simplejson'
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/simplejson/simplejson/archive/v$pkgver.tar.gz")
+sha512sums=('41e9bfad5e9263b050109adeec28bdcb190230a26e8a48db86d24fa8729517e3eacd3c3905ff9900cc9a5a90fff006e8fb92a5ac85249922a0c46ab6391ee78b')
+
+prepare() {
+  cp -a simplejson-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/simplejson-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/simplejson-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/simplejson-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/simplejson-$pkgver-py2
+  python2 setup.py pytest 
+}
+
+package_python-simplejson() {
+  depends=('python')
+
+  cd simplejson-$pkgver
+  python setup.py install --root="$pkgdir"
+  install -Dm644 "$srcdir"/simplejson-$pkgver/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-simplejson() {
+  depends=('python2')
+
+  cd simplejson-$pkgver-py2
+  python2 setup.py install --root="$pkgdir"
+  install -Dm644 "$srcdir"/simplejson-$pkgver/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
+