[arch-commits] Commit in python-idna/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:04:06
  Author: felixonmars
Revision: 365664

archrelease: copy trunk to staging-any

Added:
  python-idna/repos/staging-any/
  python-idna/repos/staging-any/PKGBUILD
    (from rev 365663, python-idna/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-idna/repos/staging-any/PKGBUILD (from rev 365663, python-idna/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-10-25 16:04:06 UTC (rev 365664)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-idna
+pkgname=('python-idna' 'python2-idna')
+pkgver=2.8
+pkgrel=2
+pkgdesc="Internationalized Domain Names in Applications (IDNA)"
+arch=('any')
+license=('BSD')
+url="https://github.com/kjd/idna"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("https://pypi.io/packages/source/i/idna/idna-$pkgver.tar.gz")
+sha512sums=('8ca5cfe6350c51250bafdac7c6e4ddd54c4a5d6bf7acbcef896760a759868c8e9df1fdf550121d8512fa3eb316dcf031ec6058e03b4f66eadee21b63e2187d33')
+
+prepare() {
+   rm -r idna-$pkgver/*.egg-info
+   cp -a idna-$pkgver{,-py2}
+}
+
+build() {
+   cd "$srcdir"/idna-$pkgver
+   python setup.py build
+ 
+   cd "$srcdir"/idna-$pkgver-py2
+   python2 setup.py build
+}
+
+check() {
+   cd "$srcdir"/idna-$pkgver
+   python setup.py test
+
+   cd "$srcdir"/idna-$pkgver-py2
+   python2 setup.py test
+}
+ 
+package_python-idna() {
+   depends=('python')
+ 
+   cd idna-$pkgver
+   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+   install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
+ 
+package_python2-idna() {
+   depends=('python2')
+ 
+   cd idna-$pkgver-py2
+   python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+   install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}