[arch-commits] Commit in python-tqdm/repos (2 files)

[Evangelos Foutras]

    Date: Friday, October 25, 2019 @ 16:04:42
  Author: foutrelis
Revision: 519355

archrelease: copy trunk to community-staging-any

Added:
  python-tqdm/repos/community-staging-any/
  python-tqdm/repos/community-staging-any/PKGBUILD
    (from rev 519354, python-tqdm/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-tqdm/repos/community-staging-any/PKGBUILD (from rev 519354, python-tqdm/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 16:04:42 UTC (rev 519355)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-tqdm
+pkgname=('python-tqdm' 'python2-tqdm')
+pkgver=4.28.1
+pkgrel=2
+pkgdesc='Fast, Extensible Progress Meter'
+arch=('any')
+license=('MIT' 'MPL')
+url='https://github.com/tqdm/tqdm'
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-nose' 'python2-nose' 'python-coverage' 'python2-coverage' 'flake8'
+              'python2-flake8')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/tqdm/tqdm/archive/v$pkgver.tar.gz")
+sha512sums=('6bfccb83ede76a57fbad8e46bb0642a2db0f4bceedaed3428c7abb468a1f70bf4ac8097894416be9ab026877640db48953f40688ddcdf45ee52261bd3d61551b')
+
+prepare() {
+  cp -a tqdm-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/tqdm-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/tqdm-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/tqdm-$pkgver
+  python setup.py nosetests --ignore-files="tests_perf\.py"
+
+  cd "$srcdir"/tqdm-$pkgver-py2
+  python2 setup.py nosetests --ignore-files="tests_perf\.py"
+}
+
+package_python-tqdm() {
+  depends=('python')
+
+  cd tqdm-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENCE
+}
+
+package_python2-tqdm() {
+  depends=('python2')
+
+  cd tqdm-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENCE
+
+  mv "$pkgdir"/usr/bin/tqdm{,2}
+}
+
+# vim:set ts=2 sw=2 et: