[arch-commits] Commit in python-zc.lockfile/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:05:03
  Author: felixonmars
Revision: 519359

archrelease: copy trunk to community-staging-any

Added:
  python-zc.lockfile/repos/community-staging-any/
  python-zc.lockfile/repos/community-staging-any/PKGBUILD
    (from rev 519358, python-zc.lockfile/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-zc.lockfile/repos/community-staging-any/PKGBUILD (from rev 519358, python-zc.lockfile/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 16:05:03 UTC (rev 519359)
@@ -0,0 +1,57 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+pkgbase=python-zc.lockfile
+_pkgname=${pkgbase#python-}
+pkgname=(python-$_pkgname python2-$_pkgname)
+pkgver=2.0
+pkgrel=2
+arch=('any')
+pkgdesc="Zope testing frameworks"
+url="https://github.com/zopefoundation/$_pkgname"
+license=('custom:ZPL')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-zope-testing' 'python2-zope-testing')
+source=("$pkgbase-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('bdb429c506064a83cb6fe0964aef6793cc20b5c954c208497a2c3d596213687b40be6d778490d3317de87ff997dfcfc9357f6e5225f48636148f1acdc9325350')
+
+prepare() {
+  cp -a $_pkgname-$pkgver{,-py2}
+}
+
+build() {
+  echo "Building python-$_pkgname $pkgver"
+  cd "$srcdir"/$_pkgname-$pkgver
+  python setup.py build
+
+  echo "Building python2-$_pkgname $pkgver"
+  cd "$srcdir"/$_pkgname-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  echo "Running tests on python-$_pkgname $pkgver"
+  cd "$srcdir"/$_pkgname-$pkgver
+  python setup.py test -q
+
+  echo "Running tests on python2-$_pkgname $pkgver"
+  cd "$srcdir"/$_pkgname-$pkgver-py2
+  python2 setup.py test -q
+}
+
+package_python-zc.lockfile() {
+  depends=('python')
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm 644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-zc.lockfile() {
+  depends=('python2')
+  cd $_pkgname-$pkgver-py2
+
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm 644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}