[arch-commits] Commit in python-zope-interface/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:07:55
  Author: felixonmars
Revision: 365667

archrelease: copy trunk to staging-x86_64

Added:
  python-zope-interface/repos/staging-x86_64/
  python-zope-interface/repos/staging-x86_64/PKGBUILD
    (from rev 365666, python-zope-interface/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-zope-interface/repos/staging-x86_64/PKGBUILD (from rev 365666, python-zope-interface/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-10-25 16:07:55 UTC (rev 365667)
@@ -0,0 +1,51 @@
+# Maintainer : Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+pkgbase=python-zope-interface
+pkgname=('python-zope-interface' 'python2-zope-interface')
+pkgver=4.6.0
+pkgrel=2
+license=('ZPL')
+arch=('x86_64')
+url="https://pypi.python.org/pypi/zope.interface"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-zope-event' 'python2-zope-event')
+source=("https://pypi.io/packages/source/z/zope.interface/zope.interface-$pkgver.tar.gz")
+sha512sums=('cb82144f0b228dd4d2f7cbfba130ee190265bf809d4e928262935c3b5551a3a298df4eba2dfe7ecde96fed27f39f59ab95e9c11f3eadf0fdc13f61b5c046f78f')
+
+prepare() {
+  cp -a zope.interface-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir"/zope.interface-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/zope.interface-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/zope.interface-$pkgver
+  python setup.py test
+
+  cd "$srcdir"/zope.interface-$pkgver-py2
+  python2 setup.py test
+}
+
+package_python-zope-interface() {
+  pkgdesc='Zope Interfaces for Python 3.x'
+  depends=('python')
+ 
+  cd zope.interface-$pkgver
+  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}
+
+package_python2-zope-interface(){
+  pkgdesc='Zope Interfaces for Python 2.x'
+  depends=('python2')
+
+  cd zope.interface-$pkgver-py2
+  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}