[arch-commits] Commit in youtube-dl/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:33:52
  Author: felixonmars
Revision: 519469

archrelease: copy trunk to community-staging-any

Added:
  youtube-dl/repos/community-staging-any/
  youtube-dl/repos/community-staging-any/PKGBUILD
    (from rev 519465, youtube-dl/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: youtube-dl/repos/community-staging-any/PKGBUILD (from rev 519465, youtube-dl/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 16:33:52 UTC (rev 519469)
@@ -0,0 +1,36 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Maintainer: Daniel M. Capella <polyzen at archlinux.org>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=youtube-dl
+pkgver=2019.10.22
+pkgrel=2
+pkgdesc="A small command-line program to download videos from YouTube.com and a few more sites"
+arch=('any')
+url="https://ytdl-org.github.io/youtube-dl/"
+license=('custom')
+depends=('python' 'python-setuptools')
+optdepends=('ffmpeg: for video post-processing'
+            'rtmpdump: for rtmp streams support'
+            'atomicparsley: for embedding thumbnails into m4a files'
+            'python-pycryptodome: for hlsnative downloader')
+source=(https://youtube-dl.org/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz{,.sig})
+sha256sums=('8b678129fe221cda70ac4a4ccd13372b65e9b4faa7c12cbbe4ca01ec2f378f1b'
+            'SKIP')
+validpgpkeys=('7D33D762FD6C35130481347FDB4B54CBA4826A18'  # Philipp Hagemeister
+              'ED7F5BF46B3BBED81C87368E2C393E0F18A9236D') # Sergey M.
+
+prepare() {
+  cd ${pkgname}
+  sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
+  sed -i 's|etc/fish/completions|share/fish/completions|' setup.py
+}
+
+package() {
+  cd ${pkgname}
+  python setup.py install --root="${pkgdir}/" --optimize=1
+  mv "${pkgdir}/usr/share/bash-completion/completions/youtube-dl.bash-completion" \
+     "${pkgdir}/usr/share/bash-completion/completions/youtube-dl"
+  install -Dm644 youtube-dl.zsh "${pkgdir}/usr/share/zsh/site-functions/_youtube-dl"
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}