[arch-commits] Commit in python-rfc3986/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:39:01
  Author: felixonmars
Revision: 519519

archrelease: copy trunk to community-staging-any

Added:
  python-rfc3986/repos/community-staging-any/
  python-rfc3986/repos/community-staging-any/PKGBUILD
    (from rev 519515, python-rfc3986/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: python-rfc3986/repos/community-staging-any/PKGBUILD (from rev 519515, python-rfc3986/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-25 16:39:01 UTC (rev 519519)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
+
+pkgbase=python-rfc3986
+pkgname=(python-rfc3986 python2-rfc3986)
+pkgver=1.3.2
+pkgrel=2
+pkgdesc="Validating URI References per RFC 3986"
+arch=('any')
+license=('Apache')
+url="https://rfc3986.readthedocs.org/"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("https://pypi.io/packages/source/r/rfc3986/rfc3986-$pkgver.tar.gz")
+sha512sums=('c086c55295d80ccf33dbfeff06059303119e7a407bfc405b7f75ec30413221ec58d3061d75fd3ca696b7acf9b1be1dfcc785e01280bf659a53be43ab1f300b15')
+
+prepare() {
+  cp -a rfc3986-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/rfc3986-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/rfc3986-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/rfc3986-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/rfc3986-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-rfc3986() {
+  depends=('python')
+
+  cd rfc3986-$pkgver
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-rfc3986() {
+  depends=('python2')
+
+  cd rfc3986-$pkgver-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}