[arch-commits] Commit in python-pycryptodome/repos (2 files)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 16:42:29
  Author: felixonmars
Revision: 519549

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pycryptodome/repos/community-staging-x86_64/
  python-pycryptodome/repos/community-staging-x86_64/PKGBUILD
    (from rev 519547, python-pycryptodome/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-pycryptodome/repos/community-staging-x86_64/PKGBUILD (from rev 519547, python-pycryptodome/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-25 16:42:29 UTC (rev 519549)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+
+pkgbase=python-pycryptodome
+pkgname=('python-pycryptodome' 'python2-pycryptodome')
+pkgver=3.9.0
+pkgrel=2
+license=('BSD')
+arch=('x86_64')
+url='https://www.pycryptodome.org/'
+makedepends=('gmp' 'python-setuptools' 'python2-setuptools')
+source=("pycryptodome-${pkgver}.tar.gz::https://github.com/Legrandin/pycryptodome/archive/v${pkgver}.tar.gz")
+sha512sums=('1f1490d2854c9f5ed0fbb4a41b63ef47758bf07610f7c6c5bab14c93c760dc2e62d38ff101956e3739a8609bcba83c73ec77c665fe847b2d317996134212ddf7')
+
+prepare() {
+  cp -a "pycryptodome-$pkgver"{,-python2}
+}
+
+build() {
+  cd "$srcdir/pycryptodome-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/pycryptodome-$pkgver-python2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/pycryptodome-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/pycryptodome-$pkgver-python2"
+  python2 setup.py test
+}
+
+package_python-pycryptodome() {
+  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 3."
+  depends=('python' 'gmp')
+  conflicts=('python-crypto')
+  provides=('python-crypto')
+  replaces=('python-crypto')
+
+  cd "pycryptodome-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}
+
+package_python2-pycryptodome() {
+  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 2."
+  depends=('python2' 'gmp')
+  conflicts=('python2-crypto')
+  provides=('python2-crypto')
+  replaces=('python2-crypto')
+
+  cd "pycryptodome-$pkgver-python2"
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}