[arch-commits] Commit in python-gevent/repos (2 files)

[Evangelos Foutras]

    Date: Friday, October 25, 2019 @ 19:56:47
  Author: foutrelis
Revision: 519636

archrelease: copy trunk to community-staging-x86_64

Added:
  python-gevent/repos/community-staging-x86_64/
  python-gevent/repos/community-staging-x86_64/PKGBUILD
    (from rev 519635, python-gevent/trunk/PKGBUILD)

----------+
 PKGBUILD |   77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

Copied: python-gevent/repos/community-staging-x86_64/PKGBUILD (from rev 519635, python-gevent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-25 19:56:47 UTC (rev 519636)
@@ -0,0 +1,77 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ralf Schmitt <ralf at systemexit.de>
+
+pkgbase=python-gevent
+pkgname=(python-gevent python2-gevent)
+pkgver=1.4.0
+pkgrel=2
+arch=('x86_64')
+pkgdesc="Python network library that uses greenlet and libev for easy and scalable concurrency"
+license=("MIT")
+url="http://www.gevent.org/"
+makedepends=('python-greenlet' 'python2-greenlet' 'cython' 'cython2')
+checkdepends=('lsof' 'python-perf' 'python2-perf' 'python2-virtualenv' 'python-objgraph'
+              'python2-objgraph' 'python-zope-interface' 'python2-zope-interface' 'python-dnspython'
+              'python2-dnspython' 'python-requests' 'python2-requests' 'python-zope-event'
+              'python2-zope-event' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/gevent/gevent/archive/$pkgver.tar.gz")
+sha512sums=('3cfc9de24a21f544c53aa78314641c8208fb9c7e9a8366a2310e8847982a44b09bee046a24a36fe6ec09aa060ba64c151b7c67bafd740cc510520b8dc6f3b570')
+
+prepare() {
+  sed -e 's/C.UTF-8/en_US.UTF-8/' -e '/@which/d' -i gevent-$pkgver/Makefile
+
+  cp -a gevent-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/gevent-$pkgver
+
+  EMBED=1 \
+  CYTHON=cython \
+  PYTHON=python \
+  python setup.py build
+
+  cd "$srcdir"/gevent-$pkgver-py2
+
+  EMBED=1 \
+  CYTHON=cython2 \
+  PYTHON=python2 \
+  python2 setup.py build
+}
+
+check() {
+  (
+    cd "$srcdir"/gevent-$pkgver
+    pyvenv "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python3.6/site-packages"
+    python setup.py install
+    make bench alltest
+  ) || warning "Tests failed"
+
+  (
+    cd "$srcdir"/gevent-$pkgver-py2
+    virtualenv2 "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python2.7/site-packages"
+    python setup.py install
+    PYTHON=python2 make bench alltest
+  ) || warning "Tests failed"
+}
+
+package_python-gevent() {
+  depends=('python-greenlet')
+
+  cd gevent-$pkgver
+  python setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-gevent() {
+  depends=('python2-greenlet')
+
+  cd gevent-$pkgver-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}