[arch-commits] Commit in django/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 20:02:04
  Author: felixonmars
Revision: 365707

archrelease: copy trunk to staging-any

Added:
  django/repos/staging-any/
  django/repos/staging-any/PKGBUILD
    (from rev 365706, django/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: django/repos/staging-any/PKGBUILD (from rev 365706, django/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-10-25 20:02:04 UTC (rev 365707)
@@ -0,0 +1,44 @@
+# Maintainer: Angel Velasquez <angvp at archlinux.org>
+# Maintainer: Dan McGee <dan at archlinux.org>
+# Contributor: Shahar Weiss <sweiss4 at gmx.net>
+
+pkgbase=django
+pkgname=('python-django')
+pkgver=2.2.6
+pkgrel=2
+pkgdesc="A high-level Python Web framework that encourages rapid development and clean design"
+arch=('any')
+license=('BSD')
+url="http://www.djangoproject.com/"
+checkdepends=('python-pytest')
+makedepends=('python' 'python-setuptools')
+depends=('python' 'python-setuptools' 'python-pytz' 'python-sqlparse')
+optdepends=('python-psycopg2: for PostgreSQL backend')
+source=("Django-$pkgver.tar.gz::https://www.djangoproject.com/download/$pkgver/tarball/")
+sha512sums=('1bd44543ea06b6c412b1c15a6850c4aa68b637b360c922cc6ed06e7e0b2f22142d94c8c455f5c24b8c34fa5d431b5a3d80502928b5445bc2c36a5458bd5eb627')
+
+build() {
+  cd "$srcdir/Django-$pkgver"
+  python setup.py build
+}
+
+package_python-django() {
+  cd "$srcdir/Django-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  ln -s django-admin.py "$pkgdir"/usr/bin/django-admin3.py
+  ln -s django-admin "$pkgdir"/usr/bin/django-admin3
+  install -Dm644 extras/django_bash_completion \
+    "$pkgdir"/usr/share/bash-completion/completions/django-admin.py
+  ln -s django-admin.py \
+    "$pkgdir"/usr/share/bash-completion/completions/django-admin
+  ln -s django-admin.py \
+    "$pkgdir"/usr/share/bash-completion/completions/manage.py
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+check() {
+  cd "$srcdir/Django-$pkgver"
+  PYTHONPATH="$PWD" python tests/runtests.py
+}