[arch-commits] Commit in python-msgpack/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Oct 25 20:05:35 UTC 2019


    Date: Friday, October 25, 2019 @ 20:05:35
  Author: felixonmars
Revision: 519721

archrelease: copy trunk to community-staging-x86_64

Added:
  python-msgpack/repos/community-staging-x86_64/
  python-msgpack/repos/community-staging-x86_64/PKGBUILD
    (from rev 519720, python-msgpack/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-msgpack/repos/community-staging-x86_64/PKGBUILD (from rev 519720, python-msgpack/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-25 20:05:35 UTC (rev 519721)
@@ -0,0 +1,52 @@
+# Maintainer: Johannes Löthberg <johannes at kyriasis.com>
+# Contributor: Sébastien "Seblu" Luttringer
+
+pkgbase=python-msgpack
+pkgname=('python-msgpack' 'python2-msgpack')
+pkgver=0.6.2
+pkgrel=2
+
+url='https://github.com/msgpack/msgpack-python'
+arch=('x86_64')
+license=('Apache')
+
+makedepends=('cython' 'cython2' 'python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest' 'python-six' 'python2-six')
+
+source=(msgpack-python-$pkgver.tar.gz::https://github.com/msgpack/msgpack-python/archive/v$pkgver.tar.gz)
+
+md5sums=('e751675f8e18625bf1d2ec391dd9e8fd')
+
+build() {
+  cd msgpack-python-$pkgver
+  python setup.py build --build-lib=build/python
+  python2 setup.py build --build-lib=build/python2
+  find build/python2 -type f -exec \
+    sed -i '1s,^#! \?/usr/bin/\(env \|\)python$,#!/usr/bin/python2,' {} \;
+}
+
+check() {
+  cd msgpack-python-$pkgver
+  PYTHONPATH=$PWD/build/python py.test test
+  PYTHONPATH=$PWD/build/python2 py.test2 test
+}
+
+package_python-msgpack() {
+  pkgdesc='MessagePack serializer implementation for Python'
+  depends=('python')
+
+  cd msgpack-python-$pkgver
+  python setup.py build --build-lib=build/python \
+                  install --root="$pkgdir" --optimize=1
+}
+
+package_python2-msgpack() {
+  pkgdesc='MessagePack serializer implementation for Python2'
+  depends=('python2')
+
+  cd msgpack-python-$pkgver
+  python2 setup.py build --build-lib=build/python2 \
+                   install --root="$pkgdir" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list