[arch-commits] Commit in python-mako/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Friday, October 25, 2019 @ 20:12:22
  Author: felixonmars
Revision: 365715

archrelease: copy trunk to staging-any

Added:
  python-mako/repos/staging-any/
  python-mako/repos/staging-any/PKGBUILD
    (from rev 365714, python-mako/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-mako/repos/staging-any/PKGBUILD (from rev 365714, python-mako/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-10-25 20:12:22 UTC (rev 365715)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-mako
+pkgname=('python-mako' 'python2-mako')
+pkgver=1.0.14
+pkgrel=2
+pkgdesc="A super-fast templating language that borrows the best ideas from the existing templating languages"
+arch=('any')
+url="https://www.makotemplates.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-markupsafe' 'python2-markupsafe'
+             'python-beaker' 'python2-beaker')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-mock' 'python2-mock'
+              'python-babel' 'python2-babel' 'python-pygments' 'python2-pygments'
+              'python-dogpile.cache' 'python2-dogpile.cache')
+source=("https://pypi.io/packages/source/M/Mako/Mako-$pkgver.tar.gz"{,.asc})
+sha512sums=('e9a4840f4dddd77d55ad6d3b8724f0326937c04aa9c8c578ec385c70f897419b13ffc234cc673a316de2fa8cd7060fc837cf12f2317658181f8d2eb7dd4ac88f'
+            'SKIP')
+validpgpkeys=('83AF7ACE251C13E6BB7DEFBD330239C1C4DAFEE1')  # Michael Bayer
+
+prepare() {
+  cp -a Mako-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/Mako-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/Mako-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/Mako-$pkgver
+  python setup.py ptr
+
+  cd "$srcdir"/Mako-$pkgver-py2
+  python2 setup.py ptr
+}
+
+package_python-mako() {
+  depends=('python-markupsafe' 'python-beaker' 'python-setuptools')
+
+  cd Mako-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mako() {
+  depends=('python2-markupsafe' 'python2-beaker' 'python2-setuptools')
+
+  cd Mako-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  mv "$pkgdir"/usr/bin/mako-render{,2}
+}