[arch-commits] Commit in python-py/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 04:06:47
  Author: foutrelis
Revision: 519899

archrelease: copy trunk to community-staging-any

Added:
  python-py/repos/community-staging-any/
  python-py/repos/community-staging-any/PKGBUILD
    (from rev 519897, python-py/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: python-py/repos/community-staging-any/PKGBUILD (from rev 519897, python-py/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 04:06:47 UTC (rev 519899)
@@ -0,0 +1,63 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastian Wiesner <lunaryorn googlemail com>
+# Contributor: Igor Ramos Tiburcio <irtigor at yahoo.com.br>
+# Contributor: Wieland Hoffmann <themineo+aur at gmail.com>
+# Contributor: Hervé Cauwelier <herve ¤ oursours.net>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgbase=python-py
+pkgname=('python-py' 'python2-py')
+pkgver=1.8.0
+pkgrel=2
+pkgdesc="library with cross-python path, ini-parsing, io, code, log facilities"
+arch=('any')
+license=('MIT')
+url="https://py.readthedocs.io/"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-setuptools-scm'
+             'python2-setuptools-scm' 'python-iniconfig' 'python2-iniconfig'
+             'python-apipkg' 'python2-apipkg')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/py/archive/$pkgver.tar.gz")
+sha512sums=('83c7de6cfe89f5064f5f7266739b16adf61fd8f4f77ead787e17e41b7fb4d5f68fa242eab9a04c0c1a88cc7c47e68c78256e4432c5f8eeff5ac3dc36a90cfa3a')
+
+prepare() {
+  rm -r py-$pkgver/py/_vendored_packages
+  cp -a py-$pkgver{,-py2}
+
+  export LC_CTYPE=en_US.UTF-8
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+}
+
+build() {
+  cd "$srcdir"/py-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/py-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  # Known failure: https://github.com/pytest-dev/py/issues/104
+
+  cd "$srcdir"/py-$pkgver
+  python setup.py pytest || warning "Tests failed"
+
+  cd "$srcdir"/py-$pkgver-py2
+  python2 setup.py pytest || warning "Tests failed"
+}
+
+package_python-py() {
+  depends=('python-iniconfig' 'python-apipkg')
+
+  cd py-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-py() {
+  depends=('python2-iniconfig' 'python2-apipkg')
+
+  cd py-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}