[arch-commits] Commit in python-dephell-venvs/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Oct 26 04:08:25 UTC 2019


    Date: Saturday, October 26, 2019 @ 04:08:24
  Author: felixonmars
Revision: 519909

archrelease: copy trunk to community-staging-any

Added:
  python-dephell-venvs/repos/community-staging-any/
  python-dephell-venvs/repos/community-staging-any/PKGBUILD
    (from rev 519908, python-dephell-venvs/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: python-dephell-venvs/repos/community-staging-any/PKGBUILD (from rev 519908, python-dephell-venvs/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 04:08:24 UTC (rev 519909)
@@ -0,0 +1,42 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=dephell_venvs
+pkgname=python-dephell-venvs
+pkgver=0.1.16
+pkgrel=2
+pkgdesc="Manage Python virtual environments"
+arch=('any')
+url="https://github.com/dephell/${_pkgname}"
+license=('MIT')
+depends=('python-attrs' 'python-dephell-pythons')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
+sha256sums=('3675c0a905a5c29516937c686713d9387b8f8d3f3243dccec5e203e294c9b549')
+b2sums=('7e422393772902dacfe8d8eb26257065b39fc76ea0b58f0c057f9290ec911117a2d7c45303091cbe9c61f1c8928b4c5243e7e21cde880b87245756fedeb438d3')
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    # pycache slipped into release tarballs
+    find . -name \*.pyc -delete
+}
+
+build(){
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python -m pytest
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}



More information about the arch-commits mailing list