[arch-commits] Commit in python-aiohttp/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 04:32:34
  Author: felixonmars
Revision: 520032

archrelease: copy trunk to community-staging-x86_64

Added:
  python-aiohttp/repos/community-staging-x86_64/
  python-aiohttp/repos/community-staging-x86_64/PKGBUILD
    (from rev 520031, python-aiohttp/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-aiohttp/repos/community-staging-x86_64/PKGBUILD (from rev 520031, python-aiohttp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-26 04:32:34 UTC (rev 520032)
@@ -0,0 +1,54 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Philipp A. <flying-sheep at web.de>
+
+_pkgname=aiohttp
+pkgname=python-aiohttp
+_gitcommit=6a5ab96bd9cb404b4abfd5160fe8f34a29d941e5
+pkgver=3.6.2
+pkgrel=2
+pkgdesc='HTTP client/server for asyncio'
+url='https://aiohttp.readthedocs.io'
+arch=('x86_64')
+license=('Apache')
+depends=('python' 'python-chardet' 'python-multidict' 'python-async-timeout'
+         'python-yarl' 'python-attrs' 'gunicorn')
+makedepends=('cython' 'python-setuptools' 'git')
+checkdepends=('python-pytest' 'python-pytest-runner' 'python-pytest-mock'
+              'python-pytest-timeout' 'python-async_generator' 'python-brotlipy'
+              'python-pytest-xdist' 'python-pytest-forked' 'python-pytest-cov'
+              'python-trustme' 'python-freezegun')
+source=(${pkgname}::"git+https://github.com/aio-libs/aiohttp#commit=${_gitcommit}"
+        git+https://github.com/nodejs/http-parser)
+sha512sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd ${pkgname}
+  git submodule init
+  git config submodule."vendor/http-parser".url "${srcdir}/http-parser"
+  git submodule update --recursive
+  sed 's|.install-cython ||' -i Makefile
+}
+
+build() {
+  cd ${pkgname}
+  make cythonize
+  python setup.py build
+}
+
+check() {
+  cd ${pkgname}
+  python setup.py test
+}
+
+package() {
+  cd ${pkgname}
+  python setup.py install --root="${pkgdir}" -O1 --skip-build
+}
+
+# vim: ts=2 sw=2 et: