[arch-commits] Commit in python-websockets/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 05:30:45
  Author: felixonmars
Revision: 520103

archrelease: copy trunk to community-staging-x86_64

Added:
  python-websockets/repos/community-staging-x86_64/
  python-websockets/repos/community-staging-x86_64/PKGBUILD
    (from rev 520101, python-websockets/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-websockets/repos/community-staging-x86_64/PKGBUILD (from rev 520101, python-websockets/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-10-26 05:30:45 UTC (rev 520103)
@@ -0,0 +1,38 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Sherlock Holo <sherlockya at gmail.com>
+# Contributor: user6553591 <Message on Reddit>
+
+pkgname=python-websockets
+pkgver=8.0.2
+pkgrel=2
+pkgdesc='Python implementation of the WebSocket Protocol (RFC 6455)'
+url='https://github.com/aaugustin/websockets'
+arch=('x86_64')
+license=('BSD')
+depends=('python')
+makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx-autodoc-typehints' 'python-sphinxcontrib-trio')
+source=(https://github.com/aaugustin/websockets/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('1925bb5a9e9e1c568b330e7443ab39be95393b18d0ed9fec2c6d8836296a405b0f448a3087baf738eed5094ebb9fee5795619e68cde0edfa3673c1797b984779')
+
+build() {
+  cd websockets-${pkgver}
+  python setup.py build
+  sphinx-build -b text docs docs/_build/text
+  sphinx-build -b man docs docs/_build/man
+}
+
+check() {
+  cd websockets-${pkgver}
+  python setup.py test
+}
+
+package() {
+  cd websockets-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/websockets.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: