[arch-commits] Commit in python-oauthlib/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 05:41:07
  Author: foutrelis
Revision: 520165

archrelease: copy trunk to community-staging-any

Added:
  python-oauthlib/repos/community-staging-any/
  python-oauthlib/repos/community-staging-any/PKGBUILD
    (from rev 520164, python-oauthlib/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: python-oauthlib/repos/community-staging-any/PKGBUILD (from rev 520164, python-oauthlib/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 05:41:07 UTC (rev 520165)
@@ -0,0 +1,46 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-oauthlib
+pkgname=(python-oauthlib python2-oauthlib)
+pkgver=3.1.0
+pkgrel=2
+_libname=oauthlib
+pkgdesc="A generic, spec-compliant, thorough implementation of the OAuth request-signing logic"
+arch=(any)
+url="https://github.com/idan/oauthlib"
+license=('BSD')
+source=(https://files.pythonhosted.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz)
+makedepends=(python-setuptools python2-setuptools)
+sha256sums=('bee41cc35fcca6e988463cacc3bcb8a96224f470ca547e697b604cc697b2f889')
+
+build() {
+	cd "$srcdir/$_libname-$pkgver"
+
+	rm -rf ../buildpy3; mkdir ../buildpy3
+	python setup.py build -b ../buildpy3
+
+	rm -rf ../buildpy2; mkdir ../buildpy2
+	python2 setup.py build -b ../buildpy2
+}
+
+package_python-oauthlib() {
+	depends=(python-cryptography)
+
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy3 build
+	python setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+	chmod -R a+r "$pkgdir/usr/lib"
+}
+
+package_python2-oauthlib() {
+	depends=(python2-cryptography)
+
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy2 build
+	python2 setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+	chmod -R a+r "$pkgdir/usr/lib"
+}