[arch-commits] Commit in ansible/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 06:13:19
  Author: foutrelis
Revision: 520222

archrelease: copy trunk to community-staging-any

Added:
  ansible/repos/community-staging-any/
  ansible/repos/community-staging-any/PKGBUILD
    (from rev 520221, ansible/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: ansible/repos/community-staging-any/PKGBUILD (from rev 520221, ansible/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 06:13:19 UTC (rev 520222)
@@ -0,0 +1,51 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: Chris <seitz.christoph at gmail.com>
+# Contributor: m0ikz <ndelatorre at moikz.com.ar>
+# Contributor: atweiden <archbaum at gmail.com>
+
+pkgname=ansible
+pkgver=2.8.6
+pkgrel=2
+pkgdesc='Radically simple IT automation platform'
+arch=('any')
+url='https://www.ansible.com'
+license=('GPL3')
+depends=('python' 'python-yaml' 'python-paramiko' 'python-jinja')
+provides=('python-ansible')
+replaces=('python-ansible')
+conflicts=('python-ansible')
+optdepends=('sshpass: for ssh connections with password'
+            'python-passlib: crypt values for vars_prompt'
+            'python-pyopenssl: openssl modules'
+            'python-netaddr: for the ipaddr filter'
+            'python-systemd: log to journal'
+            'python-pywinrm: connect to Windows machines'
+            'python-dnspython: for dig lookup'
+            'python-ovirt-engine-sdk: ovirt support'
+            'python-boto3: aws_s3 module'
+            'python-jmespath: json_query support'
+            'acme-tiny: openssl_certificate module')
+makedepends=('asciidoc' 'fakeroot' 'python-setuptools')
+backup=('etc/ansible/ansible.cfg')
+source=("https://releases.ansible.com/ansible/ansible-${pkgver}.tar.gz")
+sha512sums=('8e29644b4651e72bd3fbd4ca91c2a36b76e5dde9bb445d3c6e0061c315eb66e1bc507729b70d82998c1cbb25f3ef0e20d281ab8354a047193e60bf4831938418')
+
+build() {
+  cd "${srcdir}"/${pkgname}-${pkgver}
+  python setup.py build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}"
+  install -Dm644 COPYING "${pkgdir}"/usr/share/doc/ansible/COPYING
+
+  install -d "${pkgdir}"/usr/share/ansible/doc
+  cp -dpr --no-preserve=ownership ./examples "${pkgdir}"/usr/share/ansible/doc/
+  install -Dm644 examples/ansible.cfg "${pkgdir}"/etc/ansible/ansible.cfg
+
+  install -d "${pkgdir}"/usr/share/man/man1
+  cp -dpr --no-preserve=ownership docs/man/man1/*.1 "${pkgdir}"/usr/share/man/man1
+}