[arch-commits] Commit in python-requests-oauthlib/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 06:13:36
  Author: foutrelis
Revision: 520225

archrelease: copy trunk to community-staging-any

Added:
  python-requests-oauthlib/repos/community-staging-any/
  python-requests-oauthlib/repos/community-staging-any/PKGBUILD
    (from rev 520224, python-requests-oauthlib/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-requests-oauthlib/repos/community-staging-any/PKGBUILD (from rev 520224, python-requests-oauthlib/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 06:13:36 UTC (rev 520225)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastien Leduc <sebastien at sleduc.fr>
+# Contributor: Roberto Catini <roberto.catini at gmail.com>
+
+pkgbase=python-requests-oauthlib
+pkgname=('python-requests-oauthlib' 'python2-requests-oauthlib')
+pkgver=1.2.0
+pkgrel=2
+pkgdesc="First-class OAuth library support for Requests"
+arch=('any')
+url="https://pypi.python.org/pypi/requests-oauthlib"
+license=('custom:ISC')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests'
+             'python-oauthlib' 'python2-oauthlib' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-requests-mock' 'python2-requests-mock'
+              'python-mock' 'python2-mock' 'python-pyjwt' 'python2-pyjwt')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/requests/requests-oauthlib/archive/v$pkgver.tar.gz")
+sha512sums=('f684e3f8ff300eb58610deeb18b45ab411a5002bd15759e5f46ce174be8b76fb29583ccce6dd39965b31f53c0343ea8af2a1b6fa3d9d38342efdfbfb555f52f1')
+
+prepare() {
+  cp -a requests-oauthlib-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/requests-oauthlib-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/requests-oauthlib-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/requests-oauthlib-$pkgver
+  py.test
+
+  cd "$srcdir"/requests-oauthlib-$pkgver-py2
+  py.test2
+}
+
+package_python-requests-oauthlib() {
+  depends=('python-requests' 'python-oauthlib')
+
+  cd requests-oauthlib-$pkgver
+  python setup.py install --root="$pkgdir/" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-requests-oauthlib() {
+  depends=('python2-requests' 'python2-oauthlib')
+
+  cd requests-oauthlib-$pkgver-py2
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+}