[arch-commits] Commit in python-pytest-cov/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Sat Oct 26 06:14:44 UTC 2019


    Date: Saturday, October 26, 2019 @ 06:14:43
  Author: foutrelis
Revision: 520234

archrelease: copy trunk to community-staging-any

Added:
  python-pytest-cov/repos/community-staging-any/
  python-pytest-cov/repos/community-staging-any/PKGBUILD
    (from rev 520233, python-pytest-cov/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-pytest-cov/repos/community-staging-any/PKGBUILD (from rev 520233, python-pytest-cov/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 06:14:43 UTC (rev 520234)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sebastien LEDUC <sebastien at sleduc.fr>
+# Contributor: Andrey Mikhaylenko <neithere at gmail dot com>
+
+pkgbase=python-pytest-cov
+pkgname=('python-pytest-cov' 'python2-pytest-cov')
+pkgver=2.8.1
+pkgrel=2
+pkgdesc='py.test plugin for coverage reporting with support for both centralised and distributed testing, including subprocesses and multiprocessing'
+arch=('any')
+license=('MIT')
+url='https://github.com/schlamar/pytest-cov'
+makedepends=('python-coverage' 'python2-coverage' 'python-setuptools' 'python2-setuptools'
+             'python-pytest' 'python2-pytest')
+checkdepends=('python-virtualenv' 'python2-virtualenv' 'python-process-tests'
+              'python2-process-tests' 'python-pytest-cache' 'python2-pytest-cache'
+              'python-pytest-xdist' 'python2-pytest-xdist' 'python-fields' 'python2-fields')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/pytest-cov/archive/v$pkgver.tar.gz")
+sha512sums=('63e4180a5e64579c87aada2f5f3afb5bfe4c4d3f4d39d694abebb05c56761b758cb9a5ccc96569acea595b9333412f34be6b1a0e1cea8a9b580694bfa11df303')
+
+prepare() {
+  cp -a pytest-cov-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pytest-cov-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pytest-cov-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  # Hack entry points by installing it
+
+  cd "$srcdir"/pytest-cov-$pkgver
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.8/site-packages:$PYTHONPATH:$PWD/tests" py.test || warning "Tests failed"
+
+  cd "$srcdir"/pytest-cov-$pkgver-py2
+  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH:$PWD/tests" py.test2 || warning "Tests failed"
+}
+
+package_python-pytest-cov() {
+  depends=('python-pytest' 'python-coverage')
+
+  cd pytest-cov-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-pytest-cov() {
+  depends=('python2-pytest' 'python2-coverage')
+
+  cd pytest-cov-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list