[arch-commits] Commit in python-socketio/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 06:40:52
  Author: foutrelis
Revision: 520296

archrelease: copy trunk to community-staging-any

Added:
  python-socketio/repos/community-staging-any/
  python-socketio/repos/community-staging-any/PKGBUILD
    (from rev 520295, python-socketio/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: python-socketio/repos/community-staging-any/PKGBUILD (from rev 520295, python-socketio/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 06:40:52 UTC (rev 520296)
@@ -0,0 +1,66 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-socketio
+pkgname=('python-socketio' 'python2-socketio')
+pkgver=3.1.2
+pkgrel=2
+pkgdesc='Python implementation of the Socket.IO realtime server'
+url='https://github.com/miguelgrinberg/python-socketio'
+arch=('any')
+license=('MIT')
+makedepends=('python-setuptools' 'python-sphinx' 'python-six' 'python-engineio' 'python-tornado'
+             'python2-setuptools' 'python2-sphinx' 'python2-six' 'python2-engineio' 'python2-tornado')
+checkdepends=('python-pytest' 'python-mock'
+              'python2-pytest' 'python2-mock')
+options=('!makeflags')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/miguelgrinberg/python-socketio/archive/v${pkgver}.tar.gz)
+sha256sums=('a44950c0535f92b3ad6f055536f4ffc35a4be8af8f88919ec25e55c2765f5fa8')
+sha512sums=('026aa04ef3d3dd32a3617b8572e0d704ec03cb9a694059ef89325a8d766ff25f93341f1f2621b46729b9462d4927bdc7052fe051a73ea7b94046a0da0d5aaf21')
+
+prepare() {
+  cp -ra ${pkgbase}-${pkgver}{,-py2}
+}
+
+build() {
+  msg2 'Building python...'
+  (cd ${pkgbase}-${pkgver}
+    python setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build
+  )
+  msg2 'Building python2...'
+  (cd ${pkgbase}-${pkgver}-py2
+    python2 setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build2
+  )
+}
+
+check() {
+  msg2 'Checking python...'
+  (cd ${pkgbase}-${pkgver}
+    py.test -k 'not test_logger'
+  )
+}
+
+package_python-socketio() {
+  depends=('python' 'python-six' 'python-engineio')
+  optdepends=('python-tornado: tornado asyncio webserver')
+  cd ${pkgbase}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/python-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+package_python2-socketio() {
+  depends=('python2' 'python2-six' 'python2-engineio')
+  optdepends=('python2-tornado: tornado asyncio webserver')
+  cd ${pkgbase}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/python-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: