[arch-commits] Commit in python-flask-security/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Oct 26 16:01:41 UTC 2019


    Date: Saturday, October 26, 2019 @ 16:01:41
  Author: felixonmars
Revision: 520418

archrelease: copy trunk to community-staging-any

Added:
  python-flask-security/repos/community-staging-any/
  python-flask-security/repos/community-staging-any/PKGBUILD
    (from rev 520417, python-flask-security/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-flask-security/repos/community-staging-any/PKGBUILD (from rev 520417, python-flask-security/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 16:01:41 UTC (rev 520418)
@@ -0,0 +1,52 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+_pkgname=flask-security
+pkgname=python-flask-security
+pkgver=3.0.0
+pkgrel=2
+pkgdesc='Quick and simple security for Flask applications'
+url='https://github.com/mattupstate/flask-security'
+arch=('any')
+license=('MIT')
+depends=('python' 'python-flask' 'python-flask-login' 'python-flask-mail' 'python-flask-principal'
+         'python-flask-wtf' 'python-flask-babelex' 'python-itsdangerous' 'python-passlib')
+makedepends=('python-flask' 'python-flask-login' 'python-flask-mail' 'python-flask-principal'
+             'python-flask-wtf' 'python-flask-babelex' 'python-itsdangerous' 'python-passlib'
+             'python-sphinx' 'python-setuptools')
+#checkdepends=('python-pytest' 'python-pytest-runner' 'python-pytest-cov' 'python-pytest-cache'
+              #'python-mock' 'python-sqlalchemy' 'python-flask-sqlalchemy' 'python-bcrypt' 'python-pony')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/mattupstate/flask-security/archive/${pkgver}.tar.gz)
+sha512sums=('1176c154e3a4d4326fc64c6d4b986150db17b51b23003ef069596333777afd5857bc33391c46c771144422f610d669ceb96f4b5a1880b9ea374a488d6cb093f6')
+
+prepare() {
+  cd ${_pkgname}-${pkgver}
+  sed -e 's/ --translations//' \
+      -e 's/ --pep8//' \
+      -e 's/ --flakes//' \
+      -i pytest.ini
+}
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py build
+  sphinx-build -b text docs docs/_build/text
+  sphinx-build -b man docs docs/_build/man
+}
+
+# TODO: test marks not compatible with latest pytest
+#check() {
+  #cd ${_pkgname}-${pkgver}
+  #PYTHONPATH=. py.test
+  #PYTHONPATH=. py.test2
+#}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 README.rst CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/flask-security.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list