[arch-commits] Commit in python-ukpostcodeparser/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 20:21:21
  Author: felixonmars
Revision: 520476

archrelease: copy trunk to community-staging-any

Added:
  python-ukpostcodeparser/repos/community-staging-any/
  python-ukpostcodeparser/repos/community-staging-any/PKGBUILD
    (from rev 520474, python-ukpostcodeparser/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-ukpostcodeparser/repos/community-staging-any/PKGBUILD (from rev 520474, python-ukpostcodeparser/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 20:21:21 UTC (rev 520476)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-ukpostcodeparser
+pkgname=('python-ukpostcodeparser' 'python2-ukpostcodeparser')
+pkgver=1.1.2
+pkgrel=3
+pkgdesc="UK Postcode parser"
+arch=('any')
+license=('MIT')
+url="https://github.com/hamstah/ukpostcodeparser"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/hamstah/ukpostcodeparser/archive/v$pkgver.tar.gz")
+sha512sums=('8113522b728c095f937a9f53f21c369130e3e63c4fc3546dbea4ad1c53648742fb0e766b1254c76ee65d69dec585f1a90caa7d39ca540de1765ff5f989a702de')
+
+prepare() {
+  cp -a ukpostcodeparser-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/ukpostcodeparser-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/ukpostcodeparser-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  # Expected failure: https://github.com/hamstah/ukpostcodeparser/issues/8
+
+  cd "$srcdir"/ukpostcodeparser-$pkgver
+  python -m unittest discover -s ukpostcodeparser/test -p '*.py' || warning "Tests failed"
+
+  cd "$srcdir"/ukpostcodeparser-$pkgver-py2
+  python2 -m unittest discover -s ukpostcodeparser/test -p '*.py' || warning "Tests failed"
+}
+
+package_python-ukpostcodeparser() {
+  depends=('python')
+
+  cd ukpostcodeparser-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-ukpostcodeparser() {
+  depends=('python2')
+
+  cd ukpostcodeparser-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+