[arch-commits] Commit in python-factory-boy/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 20:28:18
  Author: felixonmars
Revision: 520550

archrelease: copy trunk to community-staging-any

Added:
  python-factory-boy/repos/community-staging-any/
  python-factory-boy/repos/community-staging-any/PKGBUILD
    (from rev 520548, python-factory-boy/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-factory-boy/repos/community-staging-any/PKGBUILD (from rev 520548, python-factory-boy/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 20:28:18 UTC (rev 520550)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgname=python-factory-boy
+pkgver=2.12.0
+pkgrel=2
+pkgdesc="A versatile test fixtures replacement based on thoughtbot's factory_bot for Ruby"
+url="https://github.com/FactoryBoy/factory_boy"
+license=('MIT')
+arch=('any')
+depends=('python-faker')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest-runner' 'python-flask' 'python-django' 'python-sqlalchemy'
+              'python-flask-sqlalchemy' 'python-mongoengine' 'python-mongomock')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/FactoryBoy/factory_boy/archive/$pkgver.tar.gz")
+sha512sums=('33236bc02d5331998bb210af498bea46fc9540e66af32db8fdab563193b7ae8870e7cc01c93c24a03ee23ba64bac6ca27a72bb51a264d1c7b6bf9b098c65d5d2')
+
+prepare() {
+  cd factory_boy-$pkgver
+  # Use mongomock
+  sed -i '/serverselectiontimeoutms/a is_mock=True' tests/test_mongoengine.py
+}
+
+build() {
+  cd factory_boy-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd factory_boy-$pkgver
+  python setup.py pytest
+}
+
+package() {
+  cd factory_boy-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}