[arch-commits] Commit in python-lark-parser/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, October 26, 2019 @ 20:30:04
  Author: foutrelis
Revision: 520571

archrelease: copy trunk to community-staging-any

Added:
  python-lark-parser/repos/community-staging-any/
  python-lark-parser/repos/community-staging-any/PKGBUILD
    (from rev 520570, python-lark-parser/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-lark-parser/repos/community-staging-any/PKGBUILD (from rev 520570, python-lark-parser/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 20:30:04 UTC (rev 520571)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-lark-parser
+pkgname=(python-lark-parser python2-lark-parser)
+pkgver=0.7.7
+_nearley_commit=a46b37471db486db0f6e1ce6a2934fb238346b44
+pkgrel=2
+pkgdesc="A modern parsing library"
+url="https://github.com/lark-parser/lark"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-js2py' 'python2-js2py')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/lark-parser/lark/archive/$pkgver.tar.gz"
+        "nearley-$_nearley_commit.tar.gz::https://github.com/kach/nearley/archive/$_nearley_commit.tar.gz")
+sha512sums=('380dc98daf9bec94d3fcfe9451e4537ec2a88682472b35c924631cadfc4e497fb9a520dab16ab6bf97d350fed57e95d2dbc2a1001a52dd01d897aef8d7dc2dfe'
+            'fe14909f8a1d1626f8a632e8d48bf83602923f468b7bbb819557b85ab5e384cb042241ba15525e9850f2bbd65cad12497ed0b7ff6bc86c04d78b63d0c1bb66b4')
+
+prepare() { 
+  rmdir lark-$pkgver/tests/test_nearley/nearley
+  ln -s "$srcdir"/nearley-$_nearley_commit lark-$pkgver/tests/test_nearley/nearley
+}
+
+build() {
+  cd lark-$pkgver
+  python setup.py build
+  python2 setup.py build
+}
+
+check() {
+  cd lark-$pkgver
+  python -m tests
+  python2 -m tests
+}
+
+package_python-lark-parser() {
+  depends=('python')
+
+  cd lark-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-lark-parser() {
+  depends=('python2')
+
+  cd lark-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}