[arch-commits] Commit in python-js2py/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 20:31:32
  Author: felixonmars
Revision: 520590

archrelease: copy trunk to community-staging-any

Added:
  python-js2py/repos/community-staging-any/
  python-js2py/repos/community-staging-any/PKGBUILD
    (from rev 520586, python-js2py/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-js2py/repos/community-staging-any/PKGBUILD (from rev 520586, python-js2py/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 20:31:32 UTC (rev 520590)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-js2py
+pkgname=(python-js2py python2-js2py)
+pkgver=0.66
+_commit=c0fa43f5679cf91ca8986c5747fcb07a433dc584
+pkgrel=2
+pkgdesc="JavaScript to Python Translator & JavaScript interpreter written in 100% pure Python"
+url="https://github.com/PiotrDabkowski/Js2Py"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-tzlocal' 'python2-tzlocal'
+             'python-six' 'python2-six' 'python-pyjsparser' 'python2-pyjsparser')
+checkdepends=('npm' 'python-numpy' 'python2-numpy')
+source=("$pkgbase-$_commit.tar.gz::https://github.com/PiotrDabkowski/Js2Py/archive/$_commit.tar.gz")
+sha512sums=('ef7218b04bf498e10cc2da7e511909ecd18466de3224915062c0b9a2764187dedac25c88078d80166cc1fdf680226360f6f10e83878273673afb757b8b361219')
+
+prepare() {
+  mv Js2Py-{$_commit,$pkgver}
+}
+
+build() {
+  cd Js2Py-$pkgver
+  python setup.py build
+  python2 setup.py build
+}
+
+check() {
+  cd Js2Py-$pkgver
+  python simple_test.py
+  python2 simple_test.py || warning "https://github.com/PiotrDabkowski/Js2Py/issues/149"
+}
+
+package_python-js2py() {
+  depends=('python-tzlocal' 'python-six' 'python-pyjsparser')
+
+  cd Js2Py-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}
+
+package_python2-js2py() {
+  depends=('python2-tzlocal' 'python2-six' 'python2-pyjsparser')
+
+  cd Js2Py-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}