[arch-commits] Commit in python-bottle/repos (2 files)

[Felix Yan]

    Date: Saturday, October 26, 2019 @ 20:32:09
  Author: felixonmars
Revision: 520594

archrelease: copy trunk to community-staging-any

Added:
  python-bottle/repos/community-staging-any/
  python-bottle/repos/community-staging-any/PKGBUILD
    (from rev 520593, python-bottle/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-bottle/repos/community-staging-any/PKGBUILD (from rev 520593, python-bottle/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-10-26 20:32:09 UTC (rev 520594)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Richard Murri <admin at richardmurri.com>
+# Contributor: Farhad Shahbazi <farhad at enthusiasm.cc>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgbase=python-bottle
+pkgname=("python-bottle" "python2-bottle")
+pkgver=0.12.17
+pkgrel=2
+pkgdesc="A fast and simple micro-framework for small web-applications"
+arch=(any)
+url="https://bottlepy.org"
+license=('MIT')
+options=(!emptydirs)
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-mako' 'python2-mako' 'python-jinja' 'python2-jinja' 'python-cherrypy'
+              'python2-cherrypy' 'python-twisted' 'python2-twisted' 'python-tornado'
+              'python2-tornado' 'python-paste' 'python2-paste' 'python-gevent' 'python2-gevent'
+              'python-eventlet' 'python2-eventlet')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/defnull/bottle/archive/$pkgver.tar.gz")
+sha512sums=('b79627cdb6d6187837aeb5e5e38a96285873d8f53300c3c68f2c65378042d2f05c9445af76cf70a63b8343d5be130771678d03215c194e6fae6347ccd3cad153')
+
+prepare() {
+  cp -a bottle-$pkgver{,-py2}
+  sed -i "1s/python/python2/" bottle-$pkgver-py2/bottle.py
+}
+
+check() {
+  cd "$srcdir"/bottle-$pkgver
+  # https://github.com/bottlepy/bottle/issues/791
+  python test/testall.py || warning 'Tests failed'
+
+  cd "$srcdir"/bottle-$pkgver-py2
+  python2 test/testall.py
+}
+
+package_python-bottle() {
+  depends=('python')
+
+  cd bottle-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-bottle() {
+  depends=('python2')
+
+  cd bottle-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  mv "$pkgdir"/usr/bin/bottle.py{,2}
+}