[arch-commits] Commit in lib32-primus_vk/repos (2 files)

[Giancarlo Razzolini]

    Date: Monday, October 28, 2019 @ 02:47:37
  Author: grazzolini
Revision: 520804

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-primus_vk/repos/multilib-testing-x86_64/
  lib32-primus_vk/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 520803, lib32-primus_vk/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: lib32-primus_vk/repos/multilib-testing-x86_64/PKGBUILD (from rev 520803, lib32-primus_vk/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2019-10-28 02:47:37 UTC (rev 520804)
@@ -0,0 +1,52 @@
+# Maintainer: Giancarlo Razzolini <grazzolini at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkgname=primus_vk
+pkgname=lib32-primus_vk
+pkgver=1.3
+pkgrel=1
+pkgdesc="Nvidia Vulkan offloading for Bumblebee"
+arch=('x86_64')
+url="https://github.com/felixdoerre/primus_vk"
+license=('BSD')
+depends=('lib32-nvidia-utils' 'bumblebee' 'lib32-vulkan-icd-loader' 'lib32-primus')
+makedepends=('git' 'vulkan-validation-layers')
+source=("${_pkgname}-${pkgver}::git+${url}.git#tag=v${pkgver}")
+sha512sums=('SKIP')
+
+_backports=(
+)
+
+_reverts=(
+)
+
+prepare() {
+  cd ${_pkgname}-${pkgver}
+
+  local _c
+  
+  for _c in "${_backports[@]}"; do
+    git log --oneline -1 "${_c}"  
+    git cherry-pick -n "${_c}"
+  done
+
+  for _c in "${_reverts[@]}"; do
+    git log --oneline -1 "${_c}"
+    git revert -n "${_c}"
+  done
+}
+
+build() {
+  cd ${_pkgname}-${pkgver}
+
+  export CXXFLAGS+=' -m32 -DNV_DRIVER_PATH=\"/usr/lib32/libGLX_nvidia.so.0\"'
+  make
+}
+
+package() {
+  cd "${_pkgname}-${pkgver}"
+
+  install -D libnv_vulkan_wrapper.so -t "$pkgdir"/usr/lib32/
+  install -D libprimus_vk.so -t "$pkgdir"/usr/lib32/
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/"$pkgname"/
+}