[arch-commits] Commit in haskell-libmpd/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Sep 1 06:34:36 UTC 2019


    Date: Sunday, September 1, 2019 @ 06:34:36
  Author: felixonmars
Revision: 505865

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-libmpd/repos/community-staging-x86_64/
  haskell-libmpd/repos/community-staging-x86_64/PKGBUILD
    (from rev 505864, haskell-libmpd/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-libmpd/repos/community-staging-x86_64/PKGBUILD (from rev 505864, haskell-libmpd/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-01 06:34:36 UTC (rev 505865)
@@ -0,0 +1,46 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributer: Colin Woodbury <colingw at gmail.com>
+# Contributer: Leif Warner <abimelech at gmail.com>
+# Contributor: Cedric Girard <girard.cedric at gmail.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=libmpd
+pkgname=haskell-libmpd
+pkgver=0.9.0.9
+pkgrel=4
+pkgdesc='Client library for MPD, the Music Player Daemon'
+url='https://hackage.haskell.org/package/libmpd'
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'gmp' 'haskell-attoparsec' 'haskell-bytestring' 'haskell-containers' 'haskell-data-default'
+         'haskell-filepath' 'haskell-network' 'haskell-time' 'haskell-utf8-string'
+         'haskell-primitive')
+makedepends=('ghc')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/vimus/libmpd-haskell/archive/v${pkgver}.tar.gz)
+sha512sums=('06838c27dfc8af54a8ea711828ac7df480a0235addcd9ff42a8cd3daa4d35b7d8846de15e28ec83998ed464d38558a7d74680de032f4a7a343bb8208c3753ba9')
+
+build() {
+  cd ${_hkgname}-haskell-${pkgver}
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+package() {
+  cd ${_hkgname}-haskell-${pkgver}
+  install -Dm 744 register.sh "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -Dm 744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  install -dm 755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+  runhaskell Setup copy --destdir="$pkgdir"
+
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md changelog.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  ln -s /usr/share/doc/${pkgname}/html "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list