[arch-commits] Commit in haskell-postgresql-binary/repos (2 files)

[Felix Yan]

    Date: Monday, September 2, 2019 @ 09:56:24
  Author: felixonmars
Revision: 507010

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-postgresql-binary/repos/community-staging-x86_64/
  haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD
    (from rev 507009, haskell-postgresql-binary/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD (from rev 507009, haskell-postgresql-binary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-02 09:56:24 UTC (rev 507010)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=postgresql-binary
+pkgname=haskell-postgresql-binary
+pkgver=0.12.1.3
+pkgrel=8
+pkgdesc="Encoders and decoders for the PostgreSQL's binary format"
+url="https://github.com/nikita-volkov/postgresql-binary"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base-prelude' 'haskell-binary-parser'
+         'haskell-bytestring-strict-builder' 'haskell-loch-th' 'haskell-network-ip'
+         'haskell-placeholders' 'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-uuid' 'haskell-vector')
+makedepends=('ghc' 'haskell-postgresql-libpq' 'haskell-tasty' 'haskell-tasty-quickcheck'
+             'haskell-tasty-hunit' 'haskell-quickcheck' 'haskell-quickcheck-instances'
+             'haskell-json-ast' 'haskell-conversion' 'haskell-conversion-bytestring'
+             'haskell-conversion-text' 'haskell-rerebase' 'pifpaf' 'postgresql')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a517d8fbe3c3ba154c379c01dd83b5322eece425ec4546e6bc7386836a10e7b6366415afecea82d0c9043f26caeb53dc74d071c068a0473ac0128a583d78bc16')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1 --port 5432)
+    createuser -s postgres
+    runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}