[arch-commits] Commit in opencv-gcc8/repos (3 files)

Konstantin Gizdov kgizdov at archlinux.org
Fri Sep 6 09:15:26 UTC 2019


    Date: Friday, September 6, 2019 @ 09:15:25
  Author: kgizdov
Revision: 508269

archrelease: copy trunk to community-testing-x86_64

Added:
  opencv-gcc8/repos/community-testing-x86_64/
  opencv-gcc8/repos/community-testing-x86_64/PKGBUILD
    (from rev 508268, opencv-gcc8/trunk/PKGBUILD)
  opencv-gcc8/repos/community-testing-x86_64/opencv-includedir.patch
    (from rev 508268, opencv-gcc8/trunk/opencv-includedir.patch)

-------------------------+
 PKGBUILD                |  102 ++++++++++++++++++++++++++++++++++++++++++++++
 opencv-includedir.patch |    9 ++++
 2 files changed, 111 insertions(+)

Copied: opencv-gcc8/repos/community-testing-x86_64/PKGBUILD (from rev 508268, opencv-gcc8/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-09-06 09:15:25 UTC (rev 508269)
@@ -0,0 +1,102 @@
+# Maintainer: Konstantin Gizdov <arch at kge.pw>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgbase=opencv-gcc8
+_pkgbase=opencv
+pkgname=(opencv-gcc8 opencv-gcc8-samples)
+_pkgname=${_pkgbase}
+pkgver=4.1.1
+pkgrel=1
+pkgdesc="Open Source Computer Vision Library compiled with GCC 8"
+arch=(x86_64)
+license=(BSD)
+url="https://opencv.org/"
+depends=(intel-tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 jasper ffmpeg gcc8 gcc8-libs)
+makedepends=(cmake python-numpy python-setuptools mesa eigen hdf5 lapacke gtk3 vtk glew ant java-environment)
+optdepends=('opencv-samples: samples'
+            'gtk3: for the HighGUI module and the Python bindings'
+            'vtk: for the viz module'
+            'hdf5: for the HDF5 module and the Python bindings'
+            'opencl-icd-loader: For coding with OpenCL'
+            'python-numpy: Python bindings'
+            'java-runtime: Java interface')
+source=("${_pkgbase}-$pkgver.tar.gz::https://github.com/opencv/opencv/archive/$pkgver.zip"
+        "opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz"
+        opencv-includedir.patch)
+sha256sums=('d34985c7b4283519c032e3585b30846644f56c81acba35693295ff8930f080aa'
+            '9f85d380758498d800fec26307e389620cde8b1a2e86ab51cddc5200fbe37102'
+            'a96e35c9592e655b21a62cfe04e864a10e21535ad900e5de67356b9e9f40ca10')
+
+prepare() {
+  mkdir -p build
+
+  cd ${_pkgname}-$pkgver
+  patch -p1 -i ../opencv-includedir.patch # Fix wrong include patch in pkgconfig file
+}
+
+build() {
+  cd build
+  export JAVA_HOME="/usr/lib/jvm/default"
+  # cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  CC=/usr/bin/gcc-8 \
+  CXX=/usr/bin/g++-8 \
+  cmake ../${_pkgname}-$pkgver \
+    -DWITH_OPENCL=ON \
+    -DWITH_OPENGL=ON \
+    -DWITH_TBB=ON \
+    -DOpenGL_GL_PREFERENCE=GLVND \
+    -DBUILD_WITH_DEBUG_INFO=OFF \
+    -DBUILD_TESTS=OFF \
+    -DBUILD_PERF_TESTS=OFF \
+    -DBUILD_EXAMPLES=ON \
+    -DINSTALL_C_EXAMPLES=ON \
+    -DINSTALL_PYTHON_EXAMPLES=ON \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCPU_BASELINE_DISABLE=SSE3 \
+    -DCPU_BASELINE_REQUIRE=SSE2 \
+    -DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
+    -DOPENCV_SKIP_PYTHON_LOADER=ON \
+    -DOPENCV_PYTHON3_INSTALL_PATH=$_pythonpath \
+    -DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
+    -DLAPACK_CBLAS_H="/usr/include/cblas.h" \
+    -DLAPACK_LAPACKE_H="/usr/include/lapacke.h" \
+    -DOPENCV_GENERATE_PKGCONFIG=ON \
+    -DOPENCV_ENABLE_NONFREE=ON \
+    -DOPENCV_JNI_INSTALL_PATH=lib \
+    -DOPENCV_GENERATE_SETUPVARS=OFF \
+    -DEIGEN_INCLUDE_PATH=/usr/include/eigen3
+  make
+}
+
+package_opencv-gcc8() {
+  provides=('opencv')
+  conflicts=('opencv')
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # install license file
+  install -Dm644 "$srcdir"/${_pkgname}-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/${_pkgname}
+
+  # separate samples package
+  cd "$pkgdir"/usr/share
+  mv opencv4/samples "$srcdir"/${_pkgname}-samples
+}
+
+package_opencv-gcc8-samples() {
+  pkgdesc+=" (samples)"
+  depends=("opencv-gcc8=$pkgver")
+  provides=("opencv-samples=$pkgver")
+  conflicts=("opencv-samples=$pkgver")
+  unset optdepends
+
+  mkdir -p "$pkgdir"/usr/share/opencv
+  cp -r "$srcdir"/opencv-samples "$pkgdir"/usr/share/opencv/samples
+  # fix permissions
+  chmod 755 "$pkgdir"/usr/share/opencv/samples/*
+
+  # install license file
+  install -Dm644 "$srcdir"/opencv-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/${_pkgname}
+}

Copied: opencv-gcc8/repos/community-testing-x86_64/opencv-includedir.patch (from rev 508268, opencv-gcc8/trunk/opencv-includedir.patch)
===================================================================
--- community-testing-x86_64/opencv-includedir.patch	                        (rev 0)
+++ community-testing-x86_64/opencv-includedir.patch	2019-09-06 09:15:25 UTC (rev 508269)
@@ -0,0 +1,9 @@
+diff -u -r opencv-4.0.1/cmake/templates/opencv-XXX.pc.in opencv-4.0.1-includedir/cmake/templates/opencv-XXX.pc.in
+--- opencv-4.0.1/cmake/templates/opencv-XXX.pc.in	2018-12-22 07:03:30.000000000 +0000
++++ opencv-4.0.1-includedir/cmake/templates/opencv-XXX.pc.in	2019-02-07 15:08:15.016613349 +0000
+@@ -11,4 +10,4 @@
+ Version: @OPENCV_VERSION_PLAIN@
+ Libs: @OPENCV_PC_LIBS@
+ Libs.private: @OPENCV_PC_LIBS_PRIVATE@
+-Cflags: -I${includedir_old} -I${includedir_new}
++Cflags: -I${includedir_new}


More information about the arch-commits mailing list