[arch-commits] Commit in gobject-introspection/repos/extra-x86_64 (PKGBUILD PKGBUILD)
Jan Steffens
heftig at archlinux.org
Mon Sep 9 20:26:27 UTC 2019
Date: Monday, September 9, 2019 @ 20:26:26
Author: heftig
Revision: 362079
archrelease: copy trunk to extra-x86_64
Added:
gobject-introspection/repos/extra-x86_64/PKGBUILD
(from rev 362078, gobject-introspection/trunk/PKGBUILD)
Deleted:
gobject-introspection/repos/extra-x86_64/PKGBUILD
----------+
PKGBUILD | 124 ++++++++++++++++++++++++++++++-------------------------------
1 file changed, 63 insertions(+), 61 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2019-09-09 20:26:13 UTC (rev 362078)
+++ PKGBUILD 2019-09-09 20:26:26 UTC (rev 362079)
@@ -1,61 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-
-pkgbase=gobject-introspection
-pkgname=(gobject-introspection gobject-introspection-runtime)
-pkgver=1.60.2
-pkgrel=1
-pkgdesc="Introspection system for GObject-based libraries"
-url="https://wiki.gnome.org/Projects/GObjectIntrospection"
-arch=(x86_64)
-license=(LGPL GPL)
-depends=(python-mako python-markdown)
-makedepends=(cairo git gtk-doc python-sphinx meson)
-options=(!emptydirs)
-_commit=41edb870614e12947db8e35af9846b19f1b8d71a # tags/1.60.2^0
-source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
- "git+https://gitlab.gnome.org/GNOME/glib.git#tag=2.60.4")
-sha512sums=('SKIP'
- 'SKIP')
-
-pkgver() {
- cd $pkgbase
- git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
- cd $pkgbase
-}
-
-build() {
- arch-meson $pkgbase build \
- -D cairo=true \
- -D gtk_doc=true \
- -D doctool=true \
- -D glib_src_dir="$srcdir/glib"
- ninja -C build
-}
-
-check() {
- meson test -C build
-}
-
-package_gobject-introspection() {
- depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
-
- DESTDIR="$pkgdir" meson install -C build
-
- python -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
- python -O -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
-
-### Split runtime
- mkdir -p "$srcdir/runtime/lib"
- mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
-}
-
-package_gobject-introspection-runtime() {
- pkgdesc+=" (runtime library)"
- depends=(glib2)
-
- mv "$srcdir/runtime" "$pkgdir/usr"
-}
Copied: gobject-introspection/repos/extra-x86_64/PKGBUILD (from rev 362078, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2019-09-09 20:26:26 UTC (rev 362079)
@@ -0,0 +1,63 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.62.0
+pkgrel=1
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+depends=(python-mako python-markdown)
+_glibver=2.62.0
+makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
+options=(!emptydirs)
+_commit=f330f517d8cd0bfbe67c62ba00be85dee2b338ed # tags/1.62.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
+sha512sums=('SKIP'
+ 'SKIP')
+validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip at tecnocode.co.uk>
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+}
+
+build() {
+ arch-meson $pkgbase build \
+ -D cairo=true \
+ -D gtk_doc=true \
+ -D doctool=true \
+ -D glib_src_dir="$srcdir/glib"
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package_gobject-introspection() {
+ depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+ DESTDIR="$pkgdir" meson install -C build
+
+ python -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
+ python -O -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
+
+### Split runtime
+ mkdir -p "$srcdir/runtime/lib"
+ mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
+}
+
+package_gobject-introspection-runtime() {
+ pkgdesc+=" (runtime library)"
+ depends=(glib2)
+
+ mv "$srcdir/runtime" "$pkgdir/usr"
+}
More information about the arch-commits
mailing list