[arch-commits] Commit in evince/repos (2 files)

[Jan Steffens]

    Date: Thursday, September 12, 2019 @ 19:35:30
  Author: heftig
Revision: 362323

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evince/repos/gnome-unstable-x86_64/
  evince/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362321, evince/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: evince/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362321, evince/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-12 19:35:30 UTC (rev 362323)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evince
+pkgver=3.32.0+28+gaeeb3d2d
+pkgrel=1
+pkgdesc="Document viewer (PDF, Postscript, djvu, tiff, dvi, XPS, SyncTex support with gedit, comics books (cbr,cbz,cb7 and cbt))"
+url="https://wiki.gnome.org/Apps/Evince"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre t1lib dconf libsecret libsynctex
+         gsettings-desktop-schemas gnome-desktop libarchive gst-plugins-base-libs gspell)
+makedepends=(libnautilus-extension texlive-bin gobject-introspection docbook-xsl python gtk-doc git
+             meson appstream-glib yelp-tools)
+optdepends=('texlive-bin: DVI support'
+            'gvfs: bookmark support and session saving')
+groups=(gnome)
+_commit=aeeb3d2d47bcf95ddb8a149df3f6c28284ca7c19  # gnome-3-32
+source=("git+https://gitlab.gnome.org/GNOME/evince.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+  
+build() {
+  arch-meson $pkgname build -D ps=enabled
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}