[arch-commits] Commit in totem/repos (2 files)

[Jan Steffens]

    Date: Thursday, September 12, 2019 @ 19:42:47
  Author: heftig
Revision: 362326

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  totem/repos/gnome-unstable-x86_64/
  totem/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362325, totem/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: totem/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362325, totem/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-12 19:42:47 UTC (rev 362326)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=totem
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="Movie player for the GNOME desktop based on GStreamer"
+url="https://wiki.gnome.org/Apps/Videos"
+arch=(x86_64)
+license=(GPL2 custom)
+depends=(totem-plparser iso-codes libpeas clutter-gtk clutter-gst grilo gsettings-desktop-schemas
+         dconf python-gobject python-xdg gnome-desktop gst-plugins-base gst-plugins-good
+         gst-plugins-bad)
+makedepends=(libnautilus-extension itstool docbook-xsl python-pylint
+             gobject-introspection git appstream-glib gtk-doc meson intltool)
+optdepends=('gst-plugins-ugly: Extra media codecs'
+            'gst-libav: Extra media codecs'
+            'grilo-plugins: Media discovery'
+            'python-dbus: MPRIS plugin')
+groups=(gnome)
+conflicts=(totem-plugin)
+replaces=(totem-plugin)
+_commit=3996781377b6526d85f7d066858ee89e25efcdca  # tags/V_3_34_0^0
+source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^V_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build -D enable-gtk-doc=true
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
+}