[arch-commits] Commit in gnome-settings-daemon/repos (2 files)
Jan Steffens
heftig at archlinux.org
Thu Sep 12 19:47:05 UTC 2019
Date: Thursday, September 12, 2019 @ 19:47:04
Author: heftig
Revision: 362330
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-settings-daemon/repos/gnome-unstable-x86_64/
gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 362329, gnome-settings-daemon/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362329, gnome-settings-daemon/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2019-09-12 19:47:04 UTC (rev 362330)
@@ -0,0 +1,46 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-settings-daemon
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="GNOME Settings Daemon"
+url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse libnotify systemd-libs
+ libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather geocode-glib geoclue2 nss
+ libgudev gtk3-print-backends libnm gcr)
+makedepends=(xf86-input-wacom libxslt docbook-xsl python git meson)
+checkdepends=(python-gobject python-dbusmock)
+groups=(gnome)
+_commit=6edc3450b329731d28b71c221f5c5a3e19783565 # tags/GNOME_SETTINGS_DAEMON_3_34_0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list