[arch-commits] Commit in mutter/repos (3 files)

[Jan Steffens]

    Date: Thursday, September 12, 2019 @ 21:06:54
  Author: heftig
Revision: 362345

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  mutter/repos/gnome-unstable-x86_64/
  mutter/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362344, mutter/trunk/PKGBUILD)
  mutter/repos/gnome-unstable-x86_64/mutter.install
    (from rev 362344, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 +++++++
 2 files changed, 62 insertions(+)

Copied: mutter/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362344, mutter/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-12 21:06:54 UTC (rev 362345)
@@ -0,0 +1,55 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas libcanberra
+         startup-notification zenity libsm gnome-desktop upower libxkbcommon-x11
+         gnome-settings-daemon libgudev libinput pipewire xorg-server-xwayland)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server sysprof)
+checkdepends=(xorg-server-xvfb)
+groups=(gnome)
+install=mutter.install
+_commit=8cdcf529e9acd95e903f699acfbde7f75213ebec  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # reduce overhead moving cursor or windows
+  #git cherry-pick -n a20a0d7a4563366d2cd29c32a1b95a59121e7bf5  # !283
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  # Unexpected passes in conform test
+  # Stacking test flaky
+  dbus-run-session xvfb-run -s '+iglx -noreset' meson test -C build --print-errorlogs || :
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/gnome-unstable-x86_64/mutter.install (from rev 362344, mutter/trunk/mutter.install)
===================================================================
--- gnome-unstable-x86_64/mutter.install	                        (rev 0)
+++ gnome-unstable-x86_64/mutter.install	2019-09-12 21:06:54 UTC (rev 362345)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}